Модули (исходник)
;*
;* OBJECT MODULE CREATION MODULE.
;*
;* (C) Vitamin/CAIG/2001 11.11.2003
;*
;* Описание. Набор макросов для создания объектных модулей.
;* После компиляции необходим запуск компоновочного кода, кото-
;* рый заполняет таблицу адресов и линкует все блоки в одну об-
;* ласть памяти, можно сохранять полученный файл.
;*
;* Revision from 17.11.2003
;* + возможна запись объектного модуля на диск. Существующие
;* файлы перезаписываются или переписываются.
;* + введен новый тип точек входа- константа.
;*
;* Revision from 22.11.2003
;* + изменен формат заголовка модуля- вместо смещения начала
;* таблицы адресов хранится версия файла и его флаги.
;* + сделана поддержка секций ядра- место для кернеля каждого
;* модуля.
;* X исправлена ошибка процедуры записи файла.
;* X исправлен макрос генерации заголовка- при длине имени менее
;* 8 символов неправильно заполнял заголовок файла.
;* + добавлена генерация заголовков по конкетным адресам для
;* модулей ядра.
;*
;* Revision from 16.01.2004
;* + добавлена возможность использования меток, определенных
;* в других модулях.
;* Х изменен формат заголовка.
;* Х изменен формат хранения таблицы настроек адресов. Теперь
;* там содержится информация также и о внешних точках входа.
;*
;* Revision from 7.04.2004
;* + добавлен макрос DW_ , заменяющий DW и служащий для создания
;* таблиц адресов функций.
;*
COMPADR=#6000 ;Адрес компоновочного кода
DISKBUF=#7000 ;Адрес буфера диска
;Основные типы доступных имен.
CHAR EQU 1
INTEGER EQU 2
LONG EQU 4
FLOAT EQU 8
;Атрибуты. Если установлен флаг функции, остальные флаги
;обозначают тип возвращаемого значения. UNSIGNED с флагом
;FLOAT недействителен.
CONSTANT EQU 16
UNSIGNED EQU 32
FUNCTION EQU 64
POINTER EQU 128
;Производные типы
VOID EQU 0
BYTE EQU UNSIGNED+CHAR
WORD EQU UNSIGNED+INTEGER
DWORD EQU UNSIGNED+LONG
;Флаги модуля
KERNEL_MODULE EQU 128
;Секции ядра
SYS_SECT EQU 0 ;SYSTEM
PROC_SECT EQU 1 ;PROCESSES
MEM_SECT EQU 2 ;MEMORY
COMM_SEC EQU 3 ;COMMUNICATION
CALC_SEC EQU 4 ;CALCULATION
DEV_SECT EQU 5 ;DEVICE
FS_SECT EQU 6 ;FILE SYSTEM
CONS_SECT EQU 7 ;
GUI_SECT EQU 8 ;GRAPHIC USER INTERFACE
GFX_SECT EQU 9 ;GRAPHIC
SND_SECT EQU 10 ;SOUND
USR_SECT EQU 11 ;USER
;Стартовый макрос. Настройка областей памяти.
MACRO MODULE
MODULEADR=:0
RELOCTABLE=:1
FUNCTABLE=:2
EXTNAMTAB=:3
CVERS=0
CFLAGS=0
CUREXTERN=#FF00
ENDM
;Установка версии модуля.
MACRO VERSION
CVERS=:0
ENDM
;Если модуль для компоновки ядра, указываем его секцию в кернале
MACRO KERNELSECTION
CFLAGS=:0|128
ENDM
;Точка начала компиляции модуля.
MACRO MODULESTART
ORG MODULEADR
DISPTAB=RELOCTABLE
NAMETAB=FUNCTABLE
EXTNAM=EXTNAMTAB
ENDM
;Завершение модуля. Подсчет размеров областей.
MACRO MODULEEND
CODELEN=$-MODULEADR
ADRSIZE=DISPTAB-RELOCTABLE+2
NAMSIZE=NAMETAB-FUNCTABLE+1
EXTNAMSIZ=EXTNAM-EXTNAMTAB+1
MODLEN=32+CODELEN+ADRSIZE+NAMSIZE+EXTNAMSIZ
DISPLAY "Размер кода модуля:",CODELEN
DISPLAY "Размер таблицы адресов:",ADRSIZE
DISPLAY "Размер таблицы имен:",NAMSIZE
DISPLAY "Размер таблицы имен EXTERN:",EXTNAMSIZ
DISPLAY "Размер файла:",MODLEN
ENDM
;Определение доступных имен.
;Массив записей:
;DB "FunctionName",0 -имя точки
;DB TYPE -тип точки
;DW OFFSET_FROM_CODE_BEGIN -смещение от начала кода
;... или значение константы
;DB -1 -конец списка
MACRO PUBLIC ;PUBLIC "PUBICNAME",TYPE
OLDADR=$
ORG NAMETAB
DB :S,
DB 0
DB :1
IF :1-CONSTANT
DW :2
ELSE
DW OLDADR-MODULEADR
ENDIF
DB -1
NAMETAB=$-1
ORG OLDADR
ENDM
;определение внешних имен.
;DB "EXTERNNAME",0
;DB -1
MACRO EXTERN ;EXTERN "NAME",NAME
OLDADR=$
ORG EXTNAM
DB :S,
DB 0,-1
EXTNAM=$-1
ORG OLDADR
:1=CUREXTERN
CUREXTERN=CUREXTERN+1
IF CUREXTERN
DISPLAY "Переполнение таблицы внешних точек!!!!!!"
ENDIF
ENDM
;Создание компилирующего кода.
;На входе подается имя модуля (до 16 символов).
MACRO COMPILE ;COMPILE "FILENAME"
ORG COMPADR
LD IX,RELOCTABLE ;подготовка таблицы адресов
LD DE,MODULEADR
LD BC,4
FILLA LD L,(IX)
LD H,(IX+1)
LD A,L
AND H
INC A
JR Z,ENDFIL
LD A,H
DEC A
JR Z,MOVDELTA
ADD HL,DE
LD A,(HL)
INC HL
LD H,(HL)
LD L,A
AND A
SBC HL,DE
MOVDELTA
LD (IX+2),L
LD (IX+3),H
ADD IX,BC
JR FILLA
ENDFIL
LD HL,MODULEADR+MODLEN-1 ;линковка
LD DE,MODULEADR+MODLEN+ADRSIZE+NAMSIZE+EXTNAMSIZ+31
LD BC,MODLEN
LDDR
LD HL,MODNAME
LD DE,MODULEADR
LD BC,32
LDIR
IFN ADRSIZE
LD HL,RELOCTABLE
LD BC,ADRSIZE
LDIR
ENDIF
IFN NAMSIZE
LD HL,FUNCTABLE
LD BC,NAMSIZE
LDIR
ENDIF
IFN EXTNAMSIZ
LD HL,EXTNAMTAB
LD BC,EXTNAMSIZ
LDIR
ENDIF
SAVE LD HL,DISKBUF
LD DE,0
LD BC,#0905
CALL #3D13
FINDFL
LD HL,DISKBUF
LD C,128
FINDDA LD DE,MODNAME
LD B,8
LD A,(HL)
AND A
JR Z,ENDFIN
PUSH HL
FFILL LD A,(DE)
CP (HL)
JR NZ,NEFFL
INC HL,DE
DJNZ FFILL
LD DE,EXTN
LD B,3
FFEXT LD A,(DE)
CP (HL)
JR NZ,NEFFL
INC HL,DE
DJNZ FFEXT
INC HL,HL
LD DE,MODLEN
DEC DE
INC D
LD A,(HL)
CP D
JR Z,SAVEOK
POP HL
LD (HL),1
LD A,(DISKBUF+#8F4)
INC A
LD (DISKBUF+#8F4),A
JR FINDFL
SAVEOK LD B,D
DEC D
INC DE
DEC HL
LD (HL),D
DEC HL
LD (HL),E ;LEN
INC HL,HL,HL
LD E,(HL)
INC HL
LD D,(HL)
POP HL
SAVEFF LD C,6
LD HL,MODULEADR
CALL #3D13
LD HL,DISKBUF
LD DE,0
LD BC,#0906
CALL #3D13
RET
NEFFL POP HL
LD A,L
ADD A,16
LD L,A
ADC A,H
SUB L
LD H,A
DEC C
JR NZ,FINDDA
LD A,2
OUT (-2),A
RET
Модули (исходник)
Фрагмент 3/4
ENDFIN EX DE,HL
DUP 8
LDI
EDUP
LD HL,EXTN
LDI
LDI
LDI
LD HL,MODLEN
EX DE,HL
LD (HL),E
INC HL
LD (HL),D
INC HL
DEC DE
INC D
LD (HL),D
LD B,D
INC HL
LD DE,(DISKBUF+#8E1)
LD (HL),E
INC HL
LD (HL),D
PUSH DE
LD HL,(DISKBUF+#8E1)
LD A,L
ADD A,B
CP 16
JR C,NEIVR
INC H
AND 15
NEIVR LD L,A
LD (DISKBUF+#8E1),HL
LD HL,(DISKBUF+#8E5)
LD A,L
SUB B
LD L,A
JR NC,NOCAR
DEC H
NOCAR LD (DISKBUF+#8E5),HL
LD A,(DISKBUF+#8E4)
INC A
LD (DISKBUF+#8E4),A
POP DE
JR SAVEFF
EXTN DB "obj"
MODNAME DB :S@ ;имя модуля
IFN $-MODNAME-16
DS 16-$+MODNAME,32
ENDIF
DW MODLEN ;размер кода
DB CVERS ;версия
DB CFLAGS ;флаги
DW 16+ADRSIZE ;смещение таблицы имен
DW 16+ADRSIZE+NAMSIZE ;смещение имен EXTERN
DW 16+ADRSIZE+NAMSIZE+EXTNAMSIZ ;код
DS 6
ENDM
;------макросы релокации-------------
;Макрос _ADRESS помещает инфомацию либо в таблицу настройки ло-
;кальных адресов, либо внешних функций.
;DW OFFSET_FROM_BEGIN_TO_INSERT
;DW OFFSET_FROM_BEGIN_TO_ADD
;DW -1
;Если 'OFFSET_FROM_BEGIN_TO_ADD == 255, то загружается адрес
;внешней точки.
MACRO _ADRESS
OLDADR=$
ORG DISPTAB ;LOCAL CALL
DW OLDADR+1-MODULEADR
DW 0
DW -1
DISPTAB=$-2
ORG OLDADR
ENDM
;Макрос, замеяющий стандартный DW
MACRO DW_
ORG $-1
_ADRESS :0
ORG $+1
DW :0
ENDM
;Макрос, заменяющий стандартный CALL
MACRO CALL_
_ADRESS :0
CALL :0
ENDM
;То же, что и команда JP. Нельзя использовать JP_ (HL)!!!!!!!
MACRO JP_
_ADRESS :0
JP :0
ENDM
MACRO JPZ_
_ADRESS :0
JP Z,:0
ENDM
MACRO JPNZ_
_ADRESS :0
JP NZ,:0
ENDM
MACRO JPC_
_ADRESS :0
JP C,:0
ENDM
MACRO JPNC_
_ADRESS :0
JP NC,:0
ENDM
;Универсальный макрос, заменяющий любую LD команду,
;связанную с загрузкой адресов в регистры. Распознает
;внешние и внутренние точки вызова.
;Если в качестве параметра используется адрес, он заносит
;информацию о нем в таблицу адресов.
MACRO LD_
OLDADR=$
LD :0,:1
LEN=$-OLDADR
IF (LEN-3)&(LEN-4)
OLDADR=$
ORG DISPTAB ;LOCAL NOT DEFINED
DW OLDADR-2-MODULEADR
DW 0
DW -1
DISPTAB=$-2
ORG OLDADR
ENDIF
ENDM
;-------LINKAGE MACROSES---------
MACRO DIGIT
DB :0+55
ELSE
DB :0+48
ENDIF
ENDM
;Создание файла-исходника для компоновки модулей.
MACRO MAKEHEADER ;MAKEHEADER "FILENAME",PAGE
DISPLAY "Creating header file to page ",:1
NAMEFR=MODNAME
CURPADR=0
ORG #C000,:1
MNAME DB :S,
IFN $-MNAME-8
DS 8-$+MNAME,32
ENDIF
DB "H"
DS #18
Модули (исходник)
Фрагмент 4/4
HSIZE DW 0
DW #C040
DB 0,0
DB 1
DB #F3,#76,#C7,#DD ;ключ принадлежности
DB #FD,#ED,#B0,#D9 ;к ALASM
DS 16
TXTSTART
DB 39,";Header file for modules construction."
DB 43,";(C) Vitamin/CAIG/2001 all rights reserved"
DB 1
METADR=FUNCTABLE
REPEAT
STRLEN=$
DB 0
REPEAT
DB .{METADR}
METADR=METADR+1
UNTIL .{METADR}
METADR=METADR+1
DB "=
IF CFLAGS&128
DB "ModuleStart+"
ENDIF
DB "#"
METADR=METADR+2
IF .{METADR-2}-CONSTANT
DIGIT .{METADR}>4&15
DIGIT .{METADR}&15
DIGIT .{METADR-1}>4&15
DIGIT .{METADR-1}&15
ELSE
PADR=#3F-(CFLAGS&15)*256+CURPADR
Поделитесь вашим мнением о статье