Programming — source code for object module creation macros

Tagan News #05

Modules (source)

;*
;* OBJECT MODULE CREATION MODULE.
;*
;* (C) Vitamin/CAIG/2001        11.11.2003
;*
;* Description. A set of macros for creating object modules.
;* After compilation, the linking code must be run. It fills
;* the address table and links all blocks into a single area of
;* memory; the resulting file can then be saved.
;*
;* Revision from 17.11.2003
;* + object modules can now be written to disk. Existing files
;*   are overwritten or rewritten.
;* + a new entry point type has been introduced — constant.
;*
;* Revision from 22.11.2003
;* + the module header format has changed — instead of the offset
;*   to the start of the address table, it now stores the file
;*   version and its flags.
;* + support for kernel sections has been added — space for each
;*   module's kernel.
;* X fixed a bug in the file-writing procedure.
;* X fixed the header-generation macro — when the name was less
;*   than 8 characters long, it filled the file header incorrectly.
;* + added generation of headers at specific addresses for
;*   kernel modules.
;*
;* Revision from 16.01.2004
;* + added the ability to use labels defined in other modules.
;* X changed the header format.
;* X changed the format for storing the address settings table.
;*   It now also contains information about external entry points.
;*
;* Revision from 7.04.2004
;* + added the DW_ macro, which replaces DW and is used to create
;*   function address tables.
;*

COMPADR=#6000           ;Address of the linking code
DISKBUF=#7000           ;Address of the disk buffer

;Main types of available names.
CHAR     EQU 1
INTEGER  EQU 2
LONG     EQU 4
FLOAT    EQU 8

;Attributes. If the function flag is set, the other flags
;indicate the return value type. UNSIGNED with the FLOAT flag
;is invalid.
CONSTANT EQU 16
UNSIGNED EQU 32
FUNCTION EQU 64
POINTER  EQU 128

;Derived types
VOID  EQU 0
BYTE  EQU UNSIGNED+CHAR
WORD  EQU UNSIGNED+INTEGER
DWORD EQU UNSIGNED+LONG

;Module flags
KERNEL_MODULE EQU 128

;Kernel sections
SYS_SECT  EQU 0         ;SYSTEM
PROC_SECT EQU 1         ;PROCESSES
MEM_SECT  EQU 2         ;MEMORY
COMM_SEC  EQU 3         ;COMMUNICATION
CALC_SEC  EQU 4         ;CALCULATION
DEV_SECT  EQU 5         ;DEVICE
FS_SECT   EQU 6         ;FILE SYSTEM
CONS_SECT EQU 7         ;
GUI_SECT  EQU 8         ;GRAPHIC USER INTERFACE
GFX_SECT  EQU 9         ;GRAPHIC
SND_SECT  EQU 10        ;SOUND
USR_SECT  EQU 11        ;USER

;Startup macro. Memory area configuration.

        MACRO MODULE
        MODULEADR=:0
        RELOCTABLE=:1
        FUNCTABLE=:2
        EXTNAMTAB=:3
        CVERS=0
        CFLAGS=0
        CUREXTERN=#FF00
        ENDM

;Set the module version.
        MACRO VERSION
        CVERS=:0
        ENDM

;If the module is for linking into the kernel, specify its section.
        MACRO KERNELSECTION
        CFLAGS=:0|128
        ENDM

;Start of module compilation.

        MACRO MODULESTART
        ORG MODULEADR
        DISPTAB=RELOCTABLE
        NAMETAB=FUNCTABLE
        EXTNAM=EXTNAMTAB
        ENDM

;End of module. Calculate area sizes.

        MACRO MODULEEND
        CODELEN=$-MODULEADR
        ADRSIZE=DISPTAB-RELOCTABLE+2
        NAMSIZE=NAMETAB-FUNCTABLE+1
        EXTNAMSIZ=EXTNAM-EXTNAMTAB+1

        MODLEN=32+CODELEN+ADRSIZE+NAMSIZE+EXTNAMSIZ

        DISPLAY "Module code size:",CODELEN
        DISPLAY "Address table size:",ADRSIZE
        DISPLAY "Name table size:",NAMSIZE
        DISPLAY "EXTERN name table size:",EXTNAMSIZ
        DISPLAY "File size:",MODLEN
        ENDM
;Definition of available names.
;Record array:
;DB "FunctionName",0            -entry point name
;DB TYPE                        -entry point type
;DW OFFSET_FROM_CODE_BEGIN      -offset from the beginning of the code
;...                            or constant value
;DB -1                          -end of list

        MACRO PUBLIC    ;PUBLIC "PUBICNAME",TYPE
        OLDADR=$
        ORG NAMETAB
        DB :S,
        DB 0
        DB :1
        IF :1-CONSTANT
        DW :2
        ELSE
        DW OLDADR-MODULEADR
        ENDIF
        DB -1
        NAMETAB=$-1
        ORG OLDADR
        ENDM

;Definition of external names.
;DB "EXTERNNAME",0
;DB -1

        MACRO EXTERN    ;EXTERN "NAME",NAME
        OLDADR=$
        ORG EXTNAM
        DB :S,
        DB 0,-1
        EXTNAM=$-1
        ORG OLDADR
        :1=CUREXTERN
        CUREXTERN=CUREXTERN+1

        IF CUREXTERN
        DISPLAY "External entry table overflow!!!!!!"
        ENDIF

        ENDM

;Creating the compiling code.
;The module name (up to 16 characters) is supplied as input.

        MACRO COMPILE           ;COMPILE "FILENAME"
        ORG COMPADR

        LD IX,RELOCTABLE        ;prepare the address table
        LD DE,MODULEADR
        LD BC,4

FILLA   LD L,(IX)
        LD H,(IX+1)
        LD A,L
        AND H
        INC A
        JR Z,ENDFIL
        LD A,H
        DEC A
        JR Z,MOVDELTA
        ADD HL,DE
        LD A,(HL)
        INC HL
        LD H,(HL)
        LD L,A
        AND A
        SBC HL,DE
MOVDELTA
        LD (IX+2),L
        LD (IX+3),H
        ADD IX,BC
        JR FILLA

ENDFIL
        LD HL,MODULEADR+MODLEN-1                       ;linking
        LD DE,MODULEADR+MODLEN+ADRSIZE+NAMSIZE+EXTNAMSIZ+31

        LD BC,MODLEN
        LDDR
        LD HL,MODNAME
        LD DE,MODULEADR
        LD BC,32
        LDIR

        IFN ADRSIZE
        LD HL,RELOCTABLE
        LD BC,ADRSIZE
        LDIR
        ENDIF

        IFN NAMSIZE
        LD HL,FUNCTABLE
        LD BC,NAMSIZE
        LDIR
        ENDIF

        IFN EXTNAMSIZ
        LD HL,EXTNAMTAB
        LD BC,EXTNAMSIZ
        LDIR
        ENDIF

SAVE    LD HL,DISKBUF
        LD DE,0
        LD BC,#0905
        CALL #3D13

FINDFL
        LD HL,DISKBUF
        LD C,128
FINDDA  LD DE,MODNAME
        LD B,8
        LD A,(HL)
        AND A
        JR Z,ENDFIN
        PUSH HL
FFILL   LD A,(DE)
        CP (HL)
        JR NZ,NEFFL
        INC HL,DE
        DJNZ FFILL

        LD DE,EXTN
        LD B,3
FFEXT   LD A,(DE)
        CP (HL)
        JR NZ,NEFFL
        INC HL,DE
        DJNZ FFEXT

        INC HL,HL
        LD DE,MODLEN
        DEC DE
        INC D
        LD A,(HL)
        CP D
        JR Z,SAVEOK
        POP HL
        LD (HL),1
        LD A,(DISKBUF+#8F4)
        INC A
        LD (DISKBUF+#8F4),A
        JR FINDFL
SAVEOK  LD B,D
        DEC D
        INC DE
        DEC HL
        LD (HL),D
        DEC HL
        LD (HL),E       ;LEN
        INC HL,HL,HL
        LD E,(HL)
        INC HL
        LD D,(HL)
        POP HL
SAVEFF  LD C,6
        LD HL,MODULEADR
        CALL #3D13
        LD HL,DISKBUF
        LD DE,0
        LD BC,#0906
        CALL #3D13
        RET

NEFFL   POP HL
        LD A,L
        ADD A,16
        LD L,A
        ADC A,H
        SUB L
        LD H,A
        DEC C
        JR NZ,FINDDA
        LD A,2
        OUT (-2),A
        RET

Modules (source code)

Fragment 3/4

ENDFIN  EX DE,HL
        DUP 8
        LDI
        EDUP
        LD HL,EXTN
        LDI
        LDI
        LDI
        LD HL,MODLEN
        EX DE,HL
        LD (HL),E
        INC HL
        LD (HL),D
        INC HL
        DEC DE
        INC D
        LD (HL),D
        LD B,D
        INC HL
        LD DE,(DISKBUF+#8E1)
        LD (HL),E
        INC HL
        LD (HL),D
        PUSH DE
        LD HL,(DISKBUF+#8E1)
        LD A,L
        ADD A,B
        CP 16
        JR C,NEIVR
        INC H
        AND 15
NEIVR   LD L,A
        LD (DISKBUF+#8E1),HL
        LD HL,(DISKBUF+#8E5)
        LD A,L
        SUB B
        LD L,A
        JR NC,NOCAR
        DEC H
NOCAR   LD (DISKBUF+#8E5),HL
        LD A,(DISKBUF+#8E4)
        INC A
        LD (DISKBUF+#8E4),A
        POP DE
        JR SAVEFF

EXTN    DB "obj"
MODNAME DB :S@                  ;module name
        IFN $-MODNAME-16
        DS 16-$+MODNAME,32
        ENDIF
        DW MODLEN               ;code size
        DB CVERS                ;version
        DB CFLAGS               ;flags
        DW 16+ADRSIZE           ;offset of name table
        DW 16+ADRSIZE+NAMSIZE   ;offset of EXTERN names
        DW 16+ADRSIZE+NAMSIZE+EXTNAMSIZ ;code
        DS 6
        ENDM

;------relocation macros-------------

;The _ADRESS macro places information either in the table for adjusting
;local addresses or in the table for external functions.
;DW OFFSET_FROM_BEGIN_TO_INSERT
;DW OFFSET_FROM_BEGIN_TO_ADD
;DW -1

;If 'OFFSET_FROM_BEGIN_TO_ADD == 255, the address of an
;external entry point is loaded.

        MACRO _ADRESS
        OLDADR=$

        ORG DISPTAB             ;LOCAL CALL
        DW OLDADR+1-MODULEADR
        DW 0
        DW -1
        DISPTAB=$-2

        ORG OLDADR
        ENDM

;Macro replacing the standard DW

        MACRO DW_
        ORG $-1
        _ADRESS :0
        ORG $+1
        DW :0
        ENDM

;Macro replacing the standard CALL
        MACRO CALL_
        _ADRESS :0
        CALL :0
        ENDM

;Same as the JP instruction. You must not use JP_ (HL)!!!!!!!
        MACRO JP_
        _ADRESS :0
        JP :0
        ENDM

        MACRO JPZ_
        _ADRESS :0
        JP Z,:0
        ENDM

        MACRO JPNZ_
        _ADRESS :0
        JP NZ,:0
        ENDM

        MACRO JPC_
        _ADRESS :0
        JP C,:0
        ENDM

        MACRO JPNC_
        _ADRESS :0
        JP NC,:0
        ENDM

;Universal macro replacing any LD instruction
;that loads addresses into registers. It recognizes
;external and internal call points.
;If an address is used as a parameter, it adds
;information about it to the address table.

        MACRO LD_
        OLDADR=$
        LD :0,:1
        LEN=$-OLDADR
        IF (LEN-3)&(LEN-4)
        OLDADR=$

        ORG DISPTAB                     ;LOCAL NOT DEFINED
        DW OLDADR-2-MODULEADR
        DW 0
        DW -1
        DISPTAB=$-2

        ORG OLDADR
        ENDIF
        ENDM

;-------LINKAGE MACROSES---------

        MACRO DIGIT
        DB :0+55
        ELSE
        DB :0+48
        ENDIF
        ENDM

;Creating a source file for linking modules.
        MACRO MAKEHEADER            ;MAKEHEADER "FILENAME",PAGE
        DISPLAY "Creating header file to page ",:1

        NAMEFR=MODNAME
        CURPADR=0

        ORG #C000,:1

MNAME   DB :S,
        IFN $-MNAME-8
        DS 8-$+MNAME,32
        ENDIF

        DB "H"
        DS #18
HSIZE   DW 0
        DW #C040
        DB 0,0
        DB 1
        DB #F3,#76,#C7,#DD ;ownership key
        DB #FD,#ED,#B0,#D9 ;to ALASM
        DS 16

TXTSTART
        DB 39,";Header file for modules construction."
        DB 43,";(C) Vitamin/CAIG/2001 all rights reserved"
        DB 1
        METADR=FUNCTABLE
        REPEAT

STRLEN=$
        DB 0

        REPEAT
        DB .{METADR}
        METADR=METADR+1
        UNTIL .{METADR}

        METADR=METADR+1

        DB "=

        IF CFLAGS&128
        DB "ModuleStart+"
        ENDIF
        DB "#"

        METADR=METADR+2

        IF .{METADR-2}-CONSTANT

        DIGIT .{METADR}>4&15
        DIGIT .{METADR}&15
        DIGIT .{METADR-1}>4&15
        DIGIT .{METADR-1}&15

        ELSE
        PADR=#3F-(CFLAGS&15)*256+CURPADR

Share your thoughts about the article