Memory
;*
;* MEMORY.H
;*
;* MEMORY MANAGEMENT
;*
;* (C) Vitamin/CAIG/2001 11.09.03
;*
INCLUDE "MODULE",65
INCLUDE "TYPES",66
MODULE #C000,#7000,#8000,#A000,#B000
VERSION 0
KERNELSECTION MEM_SECT
MODULESTART
;IN MEMORY TABLES KEEPS HI-ORDER BYTES OF HANDLES OF
;OWNERS. SPECIAL VALUES:
;255- UNACCESSABLE
;254- FREE
;253- SYSTEM
;128 BYTES FOR LOMEM TABLE (32K)
;64 BYTES FOR HIMEM TABLE (1M)
EXTERN "LoMemTable", LoMemTable
EXTERN "HiMemTable", HiMemTable
EXTERN "MaxPages", MaxPages
EXTERN "CurPage", CurPage
EXTERN "MemDriver", MemDriver
;------------------
PUBLIC "InitMemTables",FUNCTION
InitMemTables
LD_ HL,LoMemTable
LD B,192
IMT1 LD (HL),-2
INC L
DJNZ IMT1
LD_ A,(MaxPages)
SUB 64
NEG
LD B,A
LD_ HL,HiMemTable
LD A,63
ADDHLA
IMT2 LD (HL),-1
DEC L
DJNZ IMT2
RET
;---------------
PUBLIC "Page",FUNCTION
Page ;A-PAGE NUMBER
PUSH BC
LD C,A
LD_ A,(MaxPages)
CP C
JR NC,PERR
LD_ (CurPage),A
CP 2
JR C,P1
CP 4
JR C,P2
INC A
P2 INC A
P1 LD_ BC,(MemDriver)
PUSH BC
RET
PERR POP BC ;ERROR WHILE SELECT PAGE
MERR ;ERROR WHILE SELECT DRIVER
FPERR ;ERROR WHILE RELEASE PAGE
RETERR
;------------------
PUBLIC "SetDriver",FUNCTION
SetDriver ;A-DRIVER
CP mProfi+1
JR NC,MERR
AND A
JR Z,P128
CP mPent512
JR Z,P512
JR NC,PROF
JR SCORP
P512 LD_ DE,PENT512
LD A,32
JR SD1
P128 LD_ DE,PENT128
LD A,8
JR SD1
PROF LD_ DE,PROFI
LD A,64
JR SD1
SCORP LD_ DE,SCORPION
LD A,16
SD1
LD_ (MaxPages),A
LD_ (MemDriver),DE
RETOK
;PENTAGON 128 DRIVER
PENT128 OR 16
LD BC,32765
OUT (C),A
POP BC
RETOK
;PENTAGON 512 DRIVER
PENT512
LD C,A
AND 24
RLA
RLA
RLA
LD B,A
LD A,C
AND 7
OR B
OR 16
LD BC,32765
OUTPR OUT (C),A
POP BC
RETOK
;SCORPION 256 DRIVER
SCORPION
PUSH AF
AND 8
RLA
LD BC,#1FFD
S2 OUT (C),A
POP AF
AND 7
OR 16
LD B,#7F
JR OUTPR
;PROFI 1024 DRIVER
PROFI
PUSH AF
AND 56
RRCA
RRCA
RRCA
LD BC,#DFFD
JR S2
;------------------
PUBLIC "GetMem",FUNCTION
GetMem ;IX-HANDLE C-QUANTITY A-START ADRESS
;HL->ADRESS OR -1 AND SCF IF ERROR
CP #C0
JR NC,GM4
SUB #40
JR C,GM4
LD_ HL,LoMemTable
LD L,A
LD A,128
SUB L
LD B,A
LD D,HX
LD E,0
GM3 LD A,(HL)
CP -2
JR NZ,GM1
LD (HL),D
INC E
LD A,E
CP C
JR Z,GM2
GM6 INC HL
DJNZ GM3
LD A,E ;THERE ARE NO FREE SPACE
AND A
JR Z,GM4
GM5 DEC HL
LD (HL),-2
DEC E
JR NZ,GM5
GM4 LD HL,-1
RETERR
GM1 LD A,E ;FREE SPACE IS NOT ENOUGH
AND A
JR Z,GM6
GM5_ DEC HL
LD (HL),-2
DEC E
JR NZ,GM5_
JR GM6
GM2 LD A,L
SUB E
ADD A,#41
LD H,A
LD L,0
RET
;-------------
PUBLIC "GetPage",FUNCTION
GetPage ;IX-HANDLE A- START PAGE
JR NC,GPG3
LD C,A
LD_ HL,HiMemTable
ADD A,L
LD L,A
LD A,64
SUB C
LD B,A
GPG2 LD A,(HL)
CP -2
JR NZ,GPG1
LD A,HX
LD (HL),A
LD A,C
RETOK
GPG1 INC L
INC C
DJNZ GPG2
GPG3 LD A,-1
RETERR
;-------------
PUBLIC "CapturePage",FUNCTION
CapturePage ;IX-HANDLE A-PAGE
CP 64
JR NC,GPG3
LD_ HL,HiMemTable
ADD A,L
LD L,A
LD A,(HL)
AND A
JR NZ,GPG3
LD A,HX
LD (HL),A
RETOK
;---------------
PUBLIC "FreeMem",FUNCTION
FreeMem ;IX-HANDLE HL-ADRESS C-QUANTITY
LD A,H ;RESULT- SCF IF ERROR
LD_ HL,LoMemTable
LD L,A
FM2 LD A,HX
CP (HL)
JR NZ,FM1
LD (HL),-2
INC L
DEC C
JR NZ,FM2
RET
FM1 RETERR
;-------------
PUBLIC "FreePage",FUNCTION
FreePage ;IX-HANDLE A-PAGE
LD_ HL,HiMemTable
ADD A,L
LD L,A
LD A,HX
CP (HL)
JR NZ,FM1
LD (HL),-2
RETOK
;-------------
PUBLIC "ReleaseLoMem",FUNCTION
ReleaseLoMem ;IX-HANDLE
LD_ HL,LoMemTable
LD B,128
LD A,HX
RM2 CP (HL)
JR NZ,RM1
LD (HL),-2
RM1 INC L
DJNZ RM2
RET
;------------
PUBLIC "ReleaseHiMem",FUNCTION
ReleaseHiMem
LD_ HL,HiMemTable
LD B,64
LD A,HX
JR RM2
_GET LD C,0
G2 LD A,(DE)
CP -2
JR NZ,G1
INC C
G1 INC E
DJNZ G2
RET
;-------------
PUBLIC "MemAvail",FUNCTION
MemAvail ;FREE MEMORY AVIABLE H-HIMEM L-LOMEM
LD HL,0
LD_ DE,LoMemTable
LD B,128
CALL_ _GET
LD L,C
LD_ DE,HiMemTable
LD B,64
CALL_ _GET
LD H,C
RET
MODULEEND
COMPILE "memory"
MAKEHEADER "memory_",70
Поделитесь вашим мнением о статье