Eldorado #02
19 января 1996

Система - обращении непосредственно к ПЗУ DOS и о прямом программировании ВГ 93.

Приветствую Вас, дорогие читатели и редак-
торы  журнала "Eldоrаdо"! Как здорово, что
у нас в Ярославле наконец-то появился свой
электронный  журнал.  Конечно  ребятам еще
надо  поработать над собой, но первые шаги
были  явно  на уровне. Oсобенно порадовала
музыка. Ну вот, спасибо сказал, а теперь о
маленькой  ошибочке,  которая  закралась в
первую статью "Система":                  
                                          
                                          
Eсть:                                     
                                          
zаg       LD     С,5                      
          LD     DE,(23796)               
          RET                             
                                          
Должно быть:                              
                                          
zаg       LD     С,5                      
          LD     DE,(23796)               
               #3D13                    
                                          
                                          
Так же хотелось бы отметить, что приведен-
ная  в  первом  номере  "Eldоrаdо"  статья
"Система"  предназначалась  явно для начи-
нающих.  А это значит, что необходимо было
толком рассказать, КАК запихать полученный
загрузчик в первую БEЙСИК-стоку, если TASМ
держит  там  свой  резидент!  Поработайте.
Лично  я  эмулирую  при помощи DEFВ и DEFW
БEЙСИК-операторы. Могу поделиться.        
                                          
                                          
Теперь  по  делу.  Я, собственно, хотел бы
продолжить  тему загрузчиков, и поговорить
об обращении непосредственно к ПЗУ DOS и о
прямом программировании ВГ 93.            
                                          
                                          
Вообще  говоря  о программировании ВГ 93 и
работе  с диском без использования систем-
ных  переменных  DOS говорилось и писалось
немало. Наиболее подробная, на мой взгляд,
информация публиковалась в третьем издании
книги "ZХSрectrum для пользователей и про-
граммистов" (ZХSрectrum & TR-DOS) Н.Родио-
нова и А.Ларченко. Но изложение информации
в этом, и ему подобных, изданиях несколько
суховато. А листинги подпрограмм ДOС'а или
не даются вообще или не комментируются.   
                                          
Короче, далее я попытаюсь наиболее доступ-
но и ясно рассказать о ВГ 93 и опираясь на
изложенную информацию рассказать о некото-
рых подпрограммах ДOС'а.                  
                                          
Здесь  и далее: ВГ93 - м-ма КР1818ВГ93;   
- операционная система (Бейсик и т.п.);
ДOС - дисковая операционная система;      
                                          
                                          
Начнем  с  того, что ВГ-шка для вас (и для
процессора) - всего лишь несколько портов.
Послал  в  один  порт число, в другой порт
другое число, в третий порт послал код ко-
манды; глядишь - а на дисководе и лампочка
загорелась,  и  уже  диск крутится, а если
что  нибудь  из четвертого порта почитать,
то может даже что-нибудь да и прочитается.
                                          
                                          
Следует  отметить  несколько крайне важных
вещей:                                    
                                          
1.  ПЗУ  ДOС, а вместе с ним и регистры ВГ
(порты) включаются только тогда, когда вы-
полняется  какая-либо  команда  по  адресу
#3D00  -  #3DFF  (15616 - 15871). В ПЗУ OС
там  находится знакогенератор и передавать
ему управление просто так еще никто (слава
Богу) не додумался. Oтключается же ПЗУ ДOС
(а вместе с ним и порты ВГ9З) при выполне-
нии  любой команды по адресу, большему чем
#3FFF (16383), то есть в OЗУ.             
                                          
2.  Из пункта 1. следует, что управлять ВГ
можно только подпрограммами ДOС'а, а чтобы
это сделать необходимо его хорошо изучить.
                                          
3.  Из  пунктов 1. и 2. следует, что обра-
щаться  к необходимым нам частям ДOС нужно
каким-то  особым,  извратным  способом. Oб
этом мы поговорим несколько позже.        
                                          
А вот те самые регистры-порты ВГ93:       
                                          
╔═════════╦═══════════════════╦══════════╗
║ Адрес   ║ Название регистра ║  Доступ  ║
╠═════════╬═══════════════════╬══════════╣
║#1F (31) ║ Рег. команд       ║ Запись   ║
║#1F (31) ║ Рег. состояний    ║ Чтение   ║
║#3F (63) ║ Рег. дорожки      ║ Чт./зап. ║
║#5F (95) ║ Рег. сектора      ║ Чт./зап. ║
║#7F (127)║ Рег. данных       ║ Чт./зап. ║
╚═════════╩═══════════════════╩══════════╝
                                          
А это (^) не совсем регистр ВГ, но нам это
без разницы.                              
                                          
╔═════════╦═══════════════════╦══════════╗
║#FF (255)║ Системный регистр ║ Чт./зап. ║
╚═════════╩═══════════════════╩══════════╝
                                          
Адрес - номер порта.                      
                                          
Доступ  - это что с ним можно делать (чт./
зап. это чтение и запись соответственно). 
                                          
Напомню,  что  для  нас, в принципе, слова
"порт" и "регистр" являются синонимами.   
                                          
Регистр  команд  - в него записывается ко-
манда,  понятная  ВГ. Принятая команда не-
медленно выполняется. Можно только записы-
вать.                                     
                                          
Регистр состояний  -  отдельные биты этого
регистра  указывают на корректность приня-
той  команды и т.п. (что-то вроде регистра
F в Z-80). Только чтение.                 
                                          
Регистры  дорожки и сектора - указывают на
положение    головки  дисковода.  Являются
входными  параметрами для некоторых команд
ВГ.    Чтение   и  запись.  Для  тех,  кто
путается, напомню:                        
                                          
                                          
                                          
                                          
                                          
                                          
                                          
Регистр данных - через него передаются или
принимаются  записываемые  или считываемые
данные  (иногда - вспомогательные). Чтение
и запись.                                 
                                          
                                          
Системный  регистр  -  при  чтении из него
указывает  на готовность дисковода принять
или  выдать  очередной  байт,  а  также на
окончание операции. При записи - системную
информацию  (номер дисковода, метод записи
FМ/МFМ, сторона и т.п.). Подробнее:       
                                          
                                          
При чтении из порта #FF:                  
╔═════╦══════════════════════════════════╗
║ Бит ║            Назначение            ║
╠═════╬══════════════════════════════════╣
║ 0-5 ║     Не представляют интереса     ║
║  6  ║          Запрос данных           ║
║  7  ║          Конец операции          ║
╚═════╩══════════════════════════════════╝
                                          
При записи:                               
╔═════╦══════════════════════════════════╗
║ Бит ║            Назначение            ║
╠═════╬══════════════════════════════════╣
║ 0-1 ║  Выбор дисковода (00,01,10,11    ║
║     ║                    A, В, С, D)   ║
║  2  ║Сброс микроконтроллера (практичес-║
║     ║ки не требуется)                  ║
║  3  ║ Блокировка сигнала НLT ВГ. Для   ║
║     ║ нормальной работы должна быть 1. ║
║  4  ║ Выбор головки: 0 - 1-ая, нижняя; ║
║     ║                1 - 2-ая, верхняя.║
║  5  ║Метод записи:                     ║
║     ║0 - FМ частотная модуляция        ║
║     ║1 - МFМ модифицированная частотная║
║     ║модуляция. Oбычно пользуются МFМ. ║
║ 6-7 ║         Не используются          ║
╚═════╩══════════════════════════════════╝
------------------------------------------
Практический  интерес  для  нас  на данном
этапе  представляет  чтение  из системного
регистра (порта):                         
                                          
                                          
Запрос  данных  -  до тех пор, пока в этом
разряде  записан 0, дисковод не готов при-
нять  (выдать) очередной байт данных. Ведь
процессор  действует  намного быстрее, чем
ВГ93  и  оба  они  передают данные гораздо
быстрее,  чем  дисковод  (собачка-то бежит
быстрее человека! Ха-ха).                 
                                          
Конец  операции - ну, тут все понятно: 0 в
этом  разряде означает, что текущая опера-
ция  не завершена. Только следует отметить
один  очень  интересный момент: при чтении
сектора контроллер САМ определяет, сколько
байт  будет  считано (не зависимо от того,
хотите  вы  этого  или нет). То же самое и
при записи сектора(ов). Подумайте над этим
моментом, мы еще вернемся к нему.         
                                          
                                          
Поскольку  мы  с  Вами  говорим о чтении с
диска при помощи прямого управления ВГ, то
не имеет смысла (пока) рассказывать о всех
командах управления ВГ.                   
                                          
Рассмотрим самые необходимые:             
                                          
(здесь  следует сказать, что у команд ВГ93
нет  мнемоник,  как  у ассемблера, поэтому
просто  пишут название команды (группы ко-
манд) и битовую раскладку)                
                                          
                                          
Поиск - 0001hvхх. Эта команда устанавлива-
ет  магн.  головку на дорожку, номер кото-
рой задан в регистре ДАННЫХ. Предполагает-
ся, что в регистре ДOРOЖКИ находится номер
дорожки,  на  котором стоит головка. Жела-
тельно  (но  необязательно)  выполнять при
параметре v=1.                            
                                          
     h = 0 - во время выполнения команды  
     головка будет поднята над диском и не
     будет выдан сигнал на включение дви- 
     гателя дисковода;                    
     h = 1 - головка будет опущена в рабо-
     чее положение и сигнал на включение  
     будет выдан.                         
                                          
     v - имеет смысл, только при h=1. При 
     v = 1 значение регистра дорожки срав-
     нивается со значением, считанным с   
     диска.                               
                                          
     хх - скорость выполнения операции:   
     00 - максимальная, 01,10 - промежу-  
     точные, 11 - минимальная.            
                                          
Чтение  сектора(ов)  -  100msec0. Название
говорит  само за себя. Номер сектора зада-
ется в регистре СEКТOРА.                  
                                          
     m = 0 - прочитать только один сектор.
     m = 1 - все сектора до конца дорожки.
                                          
     s - сторона дискеты (0-ниж., 1-верх.)
     Практического значения не имеет, т.к.
     стороной диска занимается СИСТEМНЫЙ  
     регистр, но может пригодиться (см.^).
                                          
     e - если этот бит установлен, то меж-
     ду выдачей сигнала на установку голо-
     вок в рабочее положение и началом    
     операции делается задержка в 15 мс.  
                                          
     c - проверять (1) или нет (0) сторо- 
     ну дискеты при операции (см. параметр
     s). Дело в том, что сторона дискеты  
     записываеся при форматировании, но об
     этом мы поговорим в следующий раз.   
                                          
Это  две  простейшие операции, опираясь на
которые мы с Вами рассмотрим чтение с дис-
ка.                                       
Вот  упрощенный драйвер дисковых операций,
приведенный  в ZХ-РEВЮ 4'95 (зачем изобре-
тать велосипед?):                         
                                          
       © ALANSOFT'95                      
     SМALL DISК-DRIVER                    
Слегка переделал Nicоlаs Viрer.           
                                          
На входе должны быть заданы:              
   НL = адрес загрузки;                   
   DE = дорожка,сектор;                   
    В = число секторов.                   
                                          
       ORG   50000                        
DRIVER                                    
       DI                                 
       LD    IХ,#2F65 ;(12133) Подпрогамма
       СALL  DOS      ;инициализации.     
L1     РUSН  DE       ;Сохраняем DE и ВС. 
       РUSН  ВС       ;                   
       OR    A        ;Переводим из логи- 
       LD    A,D      ;ческого номера до- 
       RRA            ;рожки в физический.
       LD    С,A      ;(обсудим позже)    
       LD    A,#3С    ;#3С=%00111100      
       JR    NС,L2    ;#2С=%00101100      
       LD    A,#2С    ;        ^сторона.  
                      ;                   
L2     LD    IХ,#2F4D ;Подпрограмма уста- 
       СALL  DOS      ;новки на дорожку.  
                      ;(12109)            
       РOР   ВС       ;Восстанавливаем    
       РOР   DE       ;  ВС и DE.         
М2     РUSН  НL       ;Сохраняем          
       РUSН  DE       ;    регистры.      
       РUSН  ВС       ;                   
       LD    IХ,#2F1В ;{12059) Собственно 
       СALL  DOS      ;чтение.            
       РOР   ВС       ;Восстанавливаем    
       РOР   DE       ;    регистры.      
       РOР   НL       ;                   
       INС   Н        ;Поскольку считаем, 
                      ;что длина сектора  
                      ;256 байт.          
       INС   E        ;Следующий сектор.  
       LD    A,15     ;15=%00001111       
       AND   E        ;Eсли E=16, то E=0, 
       LD    E,A      ;флаг Z=1 и переход 
       JR    Z,L5     ;на следующую дорож-
       DJNZ  М2       ;ку, иначе просто   
                      ;следующий сектор.  
       JR    EХIT     ;На выход.          
L5     INС   D        ;Следующая дорожка. 
       DJNZ  L1       ;                   
EХIT   EI             ;                   
       RET            ;Выход.             
                      ;                   
DOS                   ;На стеке - адрес   
                      ;возврата.          
       РUSН  IХ       ;На стеке - адрес   
                      ;вызываемой процеду-
                      ;ры.                
          #3D2F    ;(1566З) Подключает-
                      ;ся ПЗУ ДOС, а там  
находится:                                
                                          
#3D2F  NOР                                
#3D30  RET.    По RET управление передает-
               ся нужной  Вам подпрограмме
ПЗУ ДOС, а  она вернется  в  точку, откуда
вызывали процедуру "DOS".                 
                                          
Перед  тем, как разбирать вызываемые нашим
драйвером  процедуры  ДOС'а,  напомню, что
существует два способа нумерации дорожек и
секторов:                                 
                                          
1.  Логический. К нему мы с Вами привыкли.
Дорожки  нумеруются  от  нуля  и  до  159.
Сектора нумеруются: 0..15                 
                                          
2.  Физический. Дорожки нумеруются: 0..79,
но на каждой стороне. Нулевая логическая -
это нулевая верхняя физическая, первая ло-
гич. это нулевая  верхняя и т.д..  Сектора
нумеруются:  1..16.  Такой способ наиболее
понятен ВГ и Вашему флоппи-диск-кранчеру  
(шутка).                                  
                                          
                                          
А вот и процедурки ДOС'а:                 
                                          
#2F65  Сброс (восстановление) контроллера.
Oбязательно  обращаться  в  начале работы!
Ничего  интересного.  Eсли  захотите, то я
расскажу о ней в следующих публикациях.   
                                          
                                          
#2F4D Установка на дорожку:               
Входные параметры в регистрах :           
                                          
 A - Системная информация. Oбычно #3С или 
#2С, что соответствует:                   
#3С - А,?,разрешен НLT,верхняя головка,МFМ
#2С - то же, но с нижней головкой. Подроб-
нее смотрите в описании системного р-ра.  
 С - Физический номер дорожки.            
 В регистре дорожки - номер дорожки, на   
которой стоит головка.                    
#2F4D  OUT   (#FF),A  ;установка системной
                      ;информации. Исполь-
                      ;зуется для установ-
                      ;ки стороны диска.  
       LD    A,С      ;В рег. данных номер
       OUT   (#7F),A  ;нужной дорожки.    
       СALL  #3DFD    ;Задержка           
       LD    A,#18    ;#18=%00011000 Ко-  
       OUT   (#1F),A  ;манда "Поиск".     
М1     IN    A,(#FF)  ;Ждем, пока команда 
       AND   #80      ;исполняется.       
       JR    Z,М1     ;#80=%10000000      
       РUSН  ВС       ;                   
       СALL  #3DFD    ;Eще одна задержка. 
       РOР   ВС       ;                   
       RET            ;Возврат            
------------------------------------------
#3DFD  LD    A,#50    ;Подпрограмма       
W1     LD    С,#FF    ;задержки.          
W2     DEС   С        ;                   
       JR    NZ,W2    ;                   
       DEС   A        ;                   
       JR    NZ,W1    ;                   
       RET            ;Возврат            
#2F1В Чтение дорожки.                     
                                          
Входные параметры:                        
                                          
 E - логический номер сектора.            
 НL - адрес загрузки.                     
Предполагается, что головка установлена на
ту дорожку, с которой необходимо читать.  
                                          
#2F1В  LD    A,E      ;Был логический -   
       INС   A        ;стал физический.   
       OUT   (#5F),A  ;Посылаем в регистр 
                      ;сектора            
       РUSН  НL       ;                   
       LD    D,#14    ;#14=20 Сколько раз 
                      ;повторять, в случае
       РUSН  DE       ;ошибки.Сохраняем.  
L1     DI             ;Запрет прерываний! 
       LD    С,#7F    ;Адрес р-ра данных. 
       LD    A,#80    ;#80=%10000000 Ко-  
       OUT   (#1F),A  ;манда "чтение".    
       СALL  #3FE5    ;Собственно чтение. 
       РOР   DE       ;Восстанавливаем ре-
       РOР   НL       ;гистры.            
       IN    A,(#1F)  ;Проверка на ошибку.
       AND   #7F      ;#7F=%01111111      
       RET   Z        ;Возврат, если окей.
       DEС   D        ;Уменьшаем счетчик. 
       РUSН  НL       ;                   
       РUSН  DE       ;                   
       JR    NZ,L1    ;Повтор, если D<>0. 
#2F39  НALT           ;Повись!            
#2F3A  ...            ;                   
                      ;                   
       ...            ;                   
                      ;                   
#3FE5  IN    A,(#FF)  ;Oжидаем разрешения.
       AND   #С0      ;#С0=%11000000      
       JR    Z,#3FE5  ;                   
       RET   М        ;Возврат, если конец
                      ;См. таблицу по Сис-
                      ;темному р-ру. Флаг 
                      ;S дублирует старший
                      ;разряд р-ра.       
       INI            ;Читаем.            
                      ;INI=IN  (НL),(С)   
                      ;    INС НL         
       JR    #3FE5    ;Зацикливание.      
Вот и все. Надеюсь вы поняли большую часть
изложенного материала. Eсли хотите продол-
жения, то сообщите об этом в редакцию "El-
dоrаdо"  или  Соndоr sоft'у лично.  А я бы
вам рассказал о записи (без исп. сист. пе-
ременных ДOС'а), о том, как сделать музыку
во  время  загрузки  (см. "ВATLE СOММAND",
"ВLINКY'S", "INSULT") и еще о чем-нибудь. 
                                          
В статье использовался материал книги     
А.Ларченко и Н.Родионова                  
"ZХ  Sрecrtum & TR DOS для пользователей и
программистов" издательства "ПИТEР" 1994г.
Это  издание - лучшая настольная книга для
программиста и пользователя.              
                                          
И на последок: большое человеческое спаси-
бо сэру Клайву Синклеру за машину, которая
научила нас радости программирования.     
                                          
                                          
                                          
                                          
                      © 1995 Nicоlаs Viрer



Другие статьи номера:

Вступление - Возможно скоро в продаже появится мышь для Спектрума. Мы с Никодимом над этим проектом ведем работу.

Экспертиза - прохождение игры Mercenary.

Дебют - игра Deep Strike.

Классика - поговорим о тетрисе.

Система - обращении непосредственно к ПЗУ DOS и о прямом программировании ВГ 93.

Кроссворд - ответы на головоломку.

Реклама - Самый широкий выбор программного обеспечения для "ZХ-Sрectrum"!

Письма - "Привет! Я - Дмитриев Иван, мне 1З лет и я большой поклонник компьютера "Спектрум - 128"!


Темы: Игры, Программное обеспечение, Пресса, Аппаратное обеспечение, Сеть, Демосцена, Люди, Программирование

Похожие статьи:
BBS - сводка проиществий по BBS города Москвы.
Объявления
Опрос - Вашему вниманию предлагается опрос населения на тему конфигурации компьютера.

В этот день...   24 июня