Аппаратное обеспечение — подключение мыши к ZX Spectrum через Kempston Mouse Interface

Modern #07

© Владимир Ларьков, 1996. С.-Петербург.

                 ┌──────────────────────────┐
                 ├─── ZX-SPECTRUM и МЫШЬ ───┤
                 └──────────────────────────┘

На тему подключения мышки к Спектруму уже не раз говорилось на страницах компьютерной прессы. Это были статьи рекламного характера от питерских производителей и продавцов мышиных интерфейсов. Я не буду спорить ни с одним из них, я просто хочу предложить умеющим держать в руках паяльник собрать данное устройство самостоятельно.

Для начала нужно ответить на вопрос: почему именно Kempston Mouse Interface? Ведь некоторые умельцы умудряются припаивать мышку к гнезду Kempston-джойстика, иные используют AY-mouse. Чем же Kempston Mouse Interface лучше?

Прежде всего надо заметить, что любые попытки подсоединения мыши в гнездо джойстика являются издевательством над мышью. Мышь отличает одно замечательное качество — помимо направления перемещения, она реагирует также на скорость этого самого перемещения, поэтому курсор на экране движется пропорционально движению вашей руки, т. е. когда вы двигаете мышь медленно, курсор движется также медленно, когда вы двигаете мышь быстро, курсор движется быстро. За счёт этого работать мышью несравненно удобнее, чем джойстиком. Джойстик же не способен реагировать на скорость перемещения, он учитывает только направление.

Поэтому в случае подключения мыши в гнездо джойстика, вне зависимости от того, с какой скоростью вы перемещаете мышь, курсор будет двигаться с постоянной скоростью. И на перемещение курсора от одного края экрана до другого вам может не хватить площади стола. Судя по всему, этого недостатка лишён вариант AY-mouse. Но под AY-mouse адаптировано маловато программ.

Так почему же мы так усиленно агитируем вас за Kempston Mouse Interface? Ответ банален: дело в стандартности. Это устройство придумано достаточно давно, оно является таким же стандартом, как Kempston Joystick или Sinclair Joystick, и его поддерживают фирменные программы, такие как, например, Art Studio или Artist II. Так зачем же выдумывать велосипед и плодить массу своих стандартов, если проще и логичнее использовать то, что уже придумано, тем более что под этот вариант уже существует программная поддержка.

Самое большое распространение Kempston Mouse Interface получил в Питере, это и понятно: ведь именно в Питере был сделан его русский аналог. Наряду с уже названными Art Studio и Artist II фирменную поддержку Kempston Mouse удалось найти в Victory Road, Battle Command, Carrier Command.

Очень быстро были адаптированы к Kempston Mouse Interface программы F Commander v4.01, Instrument v2.01, DCU 2.32, etc...

Новые программы стали писать с учётом факта появления на свет Kempston Mouse Interface, и поддержку мышки можно также встретить в FUT v2.01, ZXWORD v2.5m, ZxZip/ZxUnzip v1.02, Instrument v3.01, FPM v3.5 и других.

Адаптировали под Kempston Mouse Interface и игры, например: Hero Quest, Dragon Spirit, Space Crusade, A New Whole Ball Game, The A Team 1 & 2, Operation Wolf, Operation Thunderbolt, World Cup Challenge, Gunsmoke, R-Type, Gemini Wing, 1943 The Battle Begin, Zombi, Armagedon Man, etc...

Kempston Mouse Interface

Владимир Ларьков, 1996, С-Петербург

Новый электронный журнал ZX-Format с самого первого номера поддерживает Kempston Mouse Interface. Прочувствовав пожелания знакомых, Слава Медноногов вставил поддержку мышки в свою новую игру UFO II, а попробовав поиграть в неё мышью, остался очень доволен.

К чему я веду речь, вроде понятно. Количество мышиных программ неуклонно увеличивается, практически все новые питерские авторские программы имеют поддержку мышки. Фирменные программы, в которых управление мышью было бы логичным, также адаптируются под Kempston Mouse Interface. Какие ещё нужны аргументы именно за этот девайс? Вроде бы аргументов достаточно. Просто попробуйте разок посидеть в мышиной Арт Студии, после этого вас вряд ли затащишь обратно. Вы будете беситься, глядя на то, как долго ползает стрелочка, управляемая джойстиком или кнопками. В то время как с мышью всё просто порхает. И вы будете поражены, поняв, сколько времени вы тратили на простое перемещение по менюшкам.

Итак, практически все питерские программисты поддерживают стандарт Kempston Mouse Interface. Поэтому мы призываем всех юзеров спаять себе данный девайс, а всех программистов — поддерживать именно его, чтобы юзерам не приходилось слишком часто греть паяльник при появлении чего-нибудь типа Sinclair Joystick Mouse или, скажем, ZX Lprint III Mouse…

На этом вступительная часть заканчивается, переходим непосредственно к схеме. Автором схемы является Михаил Кондратьев, схема была разработана после изучения драйверов программ Art Studio и Artist. Первоначальный вариант содержал 11 корпусов, это было связано с тем, что автор использовал наиболее доступные микросхемы из тех, что были под рукой. В дальнейшем количество микросхем было сокращено до восьми. Некоторое время схема являлась коммерческим продуктом, права на неё были переданы Сергею Зонову. В прошлом году Сергей Зонов разрешил её распространение, после чего схема Kempston Mouse Interface была обнародована в электронной сети FidoNet.

В качестве самого манипулятора чаще всего используется обыкновенная серая пассивная мышь от Поиска. При минимальной цене она работает достаточно хорошо. Хотя желающие могут использовать и фирменные пассивные мыши.

При полном отсутствии в зоне видимости пассивных мышей можно использовать и активные, правда, придётся в них немного поковыряться (см. примечания к схеме).

Схема Kempston Mouse Interface:

Владимир Ларьков, 1996, С-Петербург

                 DD1              DD5
             5┌──┬──┬─┐ 6     2┌──┬──┬─┐18 D0║
         ┌────oCa│CT│0├────────┤D1│|>│1├─────╢
     Xb ─┴─ 15├──┤  │ │11     4│  │  │ │16 D1║
     ──┬──────/C │  │1├────────┤D2│  │2├─────╢
     Xa│    10│  │  │ │14     6│  │  │ │14 D2║
     ───┬─────┤U/D  │2├────────┤D3│  │3├─────╢
       ││    9├──┤  │ │ 2     8│  │  │ │12 D3║
       ││ ┌───┤R │  │3├────────┤D4│  │4├─────╢
       ││ │  1│  │  │ │      11│  │  │ │ 9 D4║
       ││ ├───┤S │  │ │  ┌─────┤D5│  │5├─────╢
       ││─┴─ 4│  │  │ │  │   13│  │  │ │ 7 D5║
       ││   ──┤0 │  │ │  │┌────┤D6│  │6├─────╢
       ││   12│  │  │ │  ││  15│  │  │ │ 5 D6║
       ││   ──┤1 │  │ │  ││┌───┤D7│  │7├─────╢
       ││   13│  │  │ │  │││ 17│  │  │ │ 3 D7║
       ││   ──┤2 │  │ │  │││┌──┤D8│  │8├─────╢
       ││    3│  │  ├─┤ 7││││19├──┤  │ │     ║
       ││   ──┤3 │  │Co─┐││││┌─oE2│  │ │     ║
       ││     └──┴──┴─┘ ││││││1│  │  │ │     ║
       ││  ┌────────────┘││││├─oE1│  │ │     ║
       ││  │     DD2     │││││ └──┴──┴─┘     ║
       ││  │ 5┌──┬──┬─┐ 6│││││ /XCS          ║
       ││  └──oCa│CT│0├──┘│││└────           ║
       ││   15├──┤  │ │11 │││                ║
       └──────/C │  │1├───┘││                ║
        │   10│  │  │ │14  ││                ║
        └─────┤U/D  │2├────┘│                ║
             9├──┤  │ │ 2   │                ║
          ┌───┤R │  │3├─────┘                ║
          │  1│  │  │ │                      ║
          ├───┤S │  │ │                      ║
         ─┴─ 4│  │  │ │                      ║
            ──┤0 │  │ │                      ║
            12│  │  │ │                      ║
            ──┤1 │  │ │                      ║
            13│  │  │ │                      ║
            ──┤2 │  │ │                      ║
             3│  │  ├─┤ 7                    ║
            ──┤3 │  │Co──                    ║
              └──┴──┴─┘                      ║
                 DD3              DD6        ║
             5┌──┬──┬─┐ 6     2┌──┬──┬─┐18 D0║
         ┌────oCa│CT│0├────────┤D1│|>│1├─────╢
     Ya ─┴─ 15├──┤  │ │11     4│  │  │ │16 D1║
     ──┬──────/C │  │1├────────┤D2│  │2├─────╢
     Yb│    10│  │  │ │14     6│  │  │ │14 D2║
     ───┬─────┤U/D  │2├────────┤D3│  │3├─────╢
       ││    9├──┤  │ │ 2     8│  │  │ │12 D3║
       ││ ┌───┤R │  │3├────────┤D4│  │4├─────╢
       ││ │  1│  │  │ │      11│  │  │ │ 9 D4║
       ││ ├───┤S │  │ │  ┌─────┤D5│  │5├─────╢
       ││─┴─ 4│  │  │ │  │   13│  │  │ │ 7 D5║
       ││   ──┤0 │  │ │  │┌────┤D6│  │6├─────╢
       ││   12│  │  │ │  ││  15│  │  │ │ 5 D6║
       ││   ──┤1 │  │ │  ││┌───┤D7│  │7├─────╢
       ││   13│  │  │ │  │││ 17│  │  │ │ 3 D7║
       ││   ──┤2 │  │ │  │││┌──┤D8│  │8├─────╢
       ││    3│  │  ├─┤ 7││││19├──┤  │ │     ║
       ││   ──┤3 │  │Co─┐││││┌─oE2│  │ │     ║
       ││     └──┴──┴─┘ ││││││1│  │  │ │     ║
       ││ ┌─────────────┘││││├─oE1│  │ │     ║
       ││ │      DD4     │││││ └──┴──┴─┘     ║
       ││ │  5┌──┬──┬─┐ 6│││││  /YCS         ║
       ││ └───oCa│CT│0├──┘│││└──────         ║
       ││   15├──┤  │ │11 │││                ║
       └──────/C │  │1├───┘││ ╔══════════════╝
        │   10│  │  │ │14  ││ ║
        └─────┤U/D  │2├────┘│ ║
             9├──┤  │ │ 2   │ ║
          ┌───┤R │  │3├─────┘ ║
          │  1│  │  │ │       ║
          ├───┤S │  │ │       ║
         ─┴─ 4│  │  │ │       ║
            ──┤0 │  │ │       ║
            12│  │  │ │       ║
            ──┤1 │  │ │       ║
            13│  │  │ │       ║

С Владимир Ларьков, 1996, С-Петербург
Фрагмент 4/6.

            ──┤2 │  │ │       ║
             3│  │  ├─┤ 7     ║
            ──┤3 │  │Co──     ║
              └──┴──┴─┘       ║
                         ╔════╝
               DD7.2     ║        DD8
     RIGHTB  5┌─┬──┐6  D0║A10 1┌─┬──┬─┐15
     ─────────┤D│|>├─────╫─────┤1│DC│0o──
             4│ │  │     ║A8  2│ │  │ │14
           ┌──oE│  │     ╟─────┤2│  │1o──
           │  └─┴──┘     ║A7  3│ │  │ │13
           │   DD7.3     ╟─────┤4│  │2o──
     LEFTB │ 9┌─┬──┐8  D1║/RD 5├─┤  │ │12
     ─────────┤D│|>├─────╫─────o&│  │3o──
           │10│ │  │     ║A0  6│ │  │ │11 /BCS
           ├──oE│  │     ╟─────┤ │  │4o───────
           │  └─┴──┘     ║    4│ │  │ │10
           │   DD7.4     ║  ┌──oS│  │5o──
     MIDLB │12┌─┬──┐11 D2║  │  │ │  │ │ 9 /XCS
     ─────────┤D│|>├─────╢  │  │ │  │6o───────
           │13│ │  │     ║  │  │ │  │ │ 7 /YCS
           ├──oE│  │     ║  │  │ │  │7o───────
           │  └─┴──┘     ║  │  └─┴──┴─┘
           │             ║  └────────────┐
           │   /BCS      ║        DD7.1  │
           └────────     ║/IORQ 2┌─┬──┐3 │
                         ╟───────┤D│|>├──┘
     DD1..DD4 - КИЕ11    ║A5    1│ │  │
     DD5, DD6 - КАП5     ╟───────oE│  │
     DD7      - КЛП8     ║       └─┴──┘
     DD8      - КИД7

Примечания:

  • Жирной линией обозначена шина Spectrum;
  • на мышь идут следующие сигналы: Xa, Xb, Ya, Yb, RIGHTB, MIDLB, LEFTB, +5V, GND;
  • /BCS, /XCS, /YCS — внутренние сигналы схемы, соединяются с одноимёнными парными на схеме;
  • схема приведена для мыши пассивного типа (мышь для «Поиска» ММП-9В), для других необходимо вывести сигналы Xa, Xb и Ya, Yb, которые берутся с оптопар после цепочки транзистор — триггер Шмидта;
  • в компьютере требуется обеспечить блокировку порта 0DFh;
  • возможна замена схемы дешифрации (DD7.1, DD8) на ПЛМ-ку типа РТ4 (РТ11), оставшийся свободный выход может использоваться для блокировки портов.

Итак, теперь поясним, каким образом работать с Kempston Mouse Interface программисту. Ничего сложного для понимания не предвидится, поскольку интерфейс довольно прост и понятен. Имеются три порта, вот их адреса: #FADF, #FBDF, #FFDF; разрядность каждого — 8 битов, т. е. байт.

#FADF — порт кнопок, значащими в нём являются младшие три бита:

0 бит — состояние правой кнопки;
1 бит — состояние левой кнопки;
2 бит — состояние средней кнопки.

При ненажатых кнопках все биты в 1. При нажатии на кнопку соответствующий бит устанавливается в 0.

По старинной традиции левая кнопка используется как выбор (Fire), правая — как отмена (Cancel). Среднюю кнопку принято использовать для дополнительных функций.

#FBDF — порт X-координаты;
#FFDF — порт Y-координаты.

По мере передвижения мыши-манипулятора значения в портах изменяются, причём ещё и циклически, т. е. при достижении #FF и дальнейшем увеличении становятся снова нулём и растут далее, опять до #FF. При движении в другую сторону картина аналогичная, только изменения происходят в обратном направлении.

Представить это дело поможет вот такая картинка:

                y^.
                 │.
                 │2
                 │1
                 │..
                 ┼─────────> x

Таким образом, необходимо считывать значения портов, и по разнице между текущим и предыдущим значением определяется направление перемещения мышки.

Владимир Ларьков, 1996, С.-Петербург

При необходимости очень точных манипуляций драйвер пишется с учётом этого, и перемещение стрелочки на одну точку производится при изменении значения, считанного из порта, на 2, 3, 5 или более единиц.

В последнее время стал модным более умный драйвер, который вначале ждёт нажатия на кнопку, и первая нажатая кнопка на мышке становится (для драйвера) левой. Сие относится только к двум крайним кнопкам, средняя кнопка — она и в Африке средняя. Это полезно для людей, привыкших держать мышь в левой руке, или на тот случай, если кто-то часто наступал на вашу мышь и одна из кнопок у неё работает хуже, чем остальные. Такой драйвер считается хорошим тоном. И если вы заметили, именно так поступает драйвер ZX-Format'а.

Проверить работу только что собранного интерфейса можно прямо из Basic'а, делая PRINT IN из портов: 79 — X, 03 — Y. При перемещении мыши значения должны изменяться циклически. При чтении из порта 23 — Fire — должны щёлкаться три младших битика при нажатии кнопочек.

И напоследок — пример драйвера Kempston Mouse, используемого в ZX-Format'е:

;MOUSE DRIVER WITH FIRE BUTTON AUTOCONFIG
;(C) Andrey Rachkin'95

        JR       MDRV

DIRECTZ DEFB  0 ;FIRE
        DEFB  0 ;UP
        DEFB  0 ;DOWN
        DEFB  0 ;RIGHT
        DEFB  0 ;LEFT
        DEFB  0 ;CANCEL

MCOORD  DEFW  0 ;LAST CURSOR COORDS
                ;IN PIXELZ
MPORTS  DEFW  0 ;LAST READED MAUSY COORDS

NONDEF  AND   3 ;HERE COMEZ BUTTONZ
                ;CONTROL IF FIRE BUTON
                ;NOT DEFINED
        JR    Z,MDRV4 ;IF NONE BUTTON
                      ;PUSHED
        CP    1
        JR    Z,NONDEF_
        XOR   A
        LD    (MDRV3+2),A
        LD    A,5
        LD    (MDRV2+2),A
NONDEF_ LD    HL,0
        LD    (MDRV1),HL
        POP   IX

; ***** MAIN PROC OF MOUSEDRIVER *****
MDRV    PUSH  IX
        LD    HL,DIRECTZ
        PUSH  HL
        POP   IX
        XOR   A
        LD    (HL),A ;CLEARING
        INC   HL     ;OF
        LD    (HL),A ;DIRECTZ
        INC   HL     ;BUFER
        LD    (HL),A
        INC   HL
        LD    (HL),A
        INC   HL
        LD    (HL),A
        INC   HL
        LD    (HL),A
        INC   HL

Владимир Ларьков, 1996, С.-Петербург
Фрагмент 6/6

        LD    BC,#FADF ;BUTTONZ CONTROL
        IN    A,(C)    ;READING FROM PORT
                       ;OF BUTTONS
        CPL
MDRV1   JR    NONDEF ;JR UNTIL FIRE
                     ;BUTTON NOT DEFINED
        RRA
MDRV2   RL    (IX+0) ;FIRE
        RRA
MDRV3   RL    (IX+5) ;CANCEL
; ***** COORDS CONTROL *****
MDRV4   LD    HL,(MCOORD) ;FORM LAST
                          ;CURSOR COORDS
        LD    DE,(MPORTS) ;FROM LAST
                          ;READED MOUSE
                          ;COORDS
        LD    BC,#FBDF
        IN    A,(C) ;READING FROM
                    ;PORT X-COORD (0-#FF)
        LD    (MPORTS),A
        SUB   E
        JR    Z,MDRV9
        JP    P,MDRV6
        LD    (IX+4),1 ;MOVE LEFT
        ADD   A,L
        JR    C,MDRV5
        XOR   A        ;MIN X-COORD
MDRV5   LD    L,A
        JR    MDRV9
MDRV6   ADD   A,L
        LD    (IX+3),1 ;MOVE RIGHT
        JR    C,MDRV7
        CP    #FE      ;MAX X-COORD
        JR    C,MDRV8
MDRV7   LD    A,#FE    ;MAX X-COORD
MDRV8   LD    L,A
MDRV9   LD    B,#FF
        IN    A,(C) ;READING FROM
                    ;PORT Y-COORD (0-#FF)
        LD    (MPORTS+1),A
        SUB   D
        JR    Z,MDRV14
        NEG
        JP    P,MDRV11
        LD    (IX+1),1 ;MOVE UP
        ADD   A,H
        JR    C,MDRV10
        XOR   A        ;MIN Y-COORD
MDRV10  LD    H,A
        JR    MDRV14
MDRV11  ADD   A,H
        LD    (IX+2),1 ;MOVE DOWN
        JR    C,MDRV12
        CP    #BF      ;MAX Y-COORD
        JR    C,MDRV13
MDRV12  LD    A,#BF    ;MAX Y-COORD
MDRV13  LD    H,A

MDRV14  LD    (MCOORD),HL ;NEW CURSOR
                          ;POSITION
                          ;IN PIXELZ
        POP      IX
        RET

                          °∙· End ·∙°

·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙∙·∙··∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·∙·

Поделитесь вашим мнением о статье