Coding — source code for a textured 3D engine without lighting

Tagan News #07
; Engine for 3D objects
; with texturing
; without lighting
;
; (c) Vitamin/CAIG/2001
;

SPD     EQU 2           ;object rotation speed
SHOWFPS EQU 1           ;show frame rate?

        ORG 24576
        LD A,23         ;clear the screens
        LD BC,32765
        OUT (C),A
        LD HL,16384
        LD DE,16385
        LD BC,6144
        LD (HL),L
        LDIR
        LD BC,767
        LD (HL),7
        LDIR
        LD HL,#D800
        LD DE,#D801
        LD BC,767
        LD (HL),7
        LDIR

        CALL UZOR               ;create the background pattern
        LD HL,16384+2048        ;copy part of it to the buffer
        LD BC,6144
        LDIR
        LD HL,16384             ;and also to the second screen
        LD DE,49152
        LD BC,6144
        LDIR

        CALL DECRUNT            ;calculate the table

LOOP
        IFN SHOWFPS     ;prepare the frame counter (if needed)
        LD HL,0
        ENDIF

        LD HL,(OBJECT)  ;rotate the object
        CALL CALCUL
PPAG    LD A,23
        LD BC,32765
        OUT (C),A

        CALL CLS        ;clear the background
        LD HL,(OBJECT)  ;build the object
        CALL BUILD

        LD A,(PPAG+1)   ;switch pages
        XOR 10
        LD (PPAG+1),A
        LD HL,RX        ;change the angles
        DUP SPD
        INC (HL)
        EDUP
        INC HL
        DUP SPD
        INC (HL)
        EDUP
        INC (HL)
        INC HL
        DUP SPD
        INC (HL)
        INC (HL)
        EDUP
        INC (HL)

        IFN SHOWFPS     ;display the frame rate
        CALL FRAMEZZ
        ENDIF

        LD A,191        ;exit? (Enter)
        IN A,(254)
        RRA
        JR C,LOOP
        RET

OBJECT  DW FIGUR1       ;what to display

;---------procedure to calculate the number of frames per second-------

        IFN SHOWFPS
FRTXT   DB "00000fps",0

FRAMEZZ
        LD DE,5000
        CALL Div
        LD HL,FRTXT
        EX DE,HL
        CALL STR
        LD HL,FRTXT+1
        LD DE,FRTXT
        LDI
        LDI
        DEC HL
        LD (HL),".
        LD HL,FRTXT
        LD DE,49152
PCY     LD A,(HL)
        AND A
        RET Z
        PUSH HL
        LD L,A
        LD H,0
        ADD HL,HL
        ADD HL,HL
        ADD HL,HL
        LD A,H
        ADD A,#3C
        LD H,A
        LD B,8
        LD C,D
P1      LD A,(HL)
        LD (DE),A
        INC L
        INC D
        DJNZ P1
        LD D,C
        INC E
        POP HL
        INC HL
        JR PCY

STR                     ;convert number to a decimal string

TWOB
        PUSH    DE
        CALL    DIVIS
        POP     DE
        CALL    DECE
        PUSH    DE
        CALL    DIVIS
        POP     DE
        CALL    DECE
        PUSH    DE
        CALL    DIVIS
        POP     DE
        CALL    DECE
        PUSH    DE
        CALL    DIVIS
        POP     DE
        CALL    DECE
        LD      A,L

DECE    ADD     A,48
ZP      LD      (DE),A
        INC     DE
        RET

DIVIS   LD A,D          ;A=HL/DE  HL=remainder
        OR E
        RET Z
        XOR A
SUBU1   SBC     HL,DE   ;a crude method, of course, but it works
        JR      C,ZI
        INC     A
        JR      SUBU1
ZI      ADD     HL,DE
        RET
        ENDIF

CLS     LD HL,32768-4096+8      ;restore the background from the buffer
        CALL FCO                ;only what was corrupted
        LD HL,32768-2048+8      ;is restored

Coding (source code) — Fragment 2/6

FCO     PUSH HL,DE
        LD B,8
CO1     LD C,255
        DUP 16
        LDI
        EDUP
        LD A,L
        ADD A,16
        LD L,A
        ADC A,H
        SUB L
        LD H,A
        LD A,E
        ADD A,16
        LD E,A
        ADC A,D
        SUB E
        LD D,A
        DJNZ CO1
        POP DE,HL
        INC D
        INC H
        LD A,H
        AND 7
        JR NZ,FCO
        RET

CALC                    ;calculate new coordinates
        PUSH IY
        LD B,(HL)
        INC HL
        INC HL
        PUSH HL
        POP IX
        LD IY,COORDS1
SSG     EXX
        LD E,(IX)       ;get the old coordinates
        LD D,(IX+1)
        LD C,(IX+2)
        CALL ROTATE     ;rotate
        LD A,E          ;and multiply the new ones by 2
        ADD A,128       ;this is done cleverly because they
        ADD A,A         ;are signed
        SUB 128
        LD (IY),A
        LD A,D
        ADD A,128
        ADD A,A
        SUB 128
        LD (IY+1),A
        LD A,C
        ADD A,128
        ADD A,A
        SUB 128
        LD (IY+2),A
        LD DE,3
        ADD IX,DE
        ADD IY,DE
        EXX
        DJNZ SSG
        POP IY
        RET

BUILD   PUSH IY         ;draw the object on screen
        LD HX,'COORDS1
        LD HY,'COORDS1
        LD A,(HL)
        ADD A,A
        ADD A,(HL)
        INC HL
        LD B,(HL)
        INC HL
        LD E,A
        LD D,0
        ADD HL,DE
PSSU    LD C,(HL)       ;read the coordinates and color
        INC HL
        LD D,(HL)
        INC HL
        LD E,(HL)
        INC HL
        LD A,(HL)
        INC HL
        PUSH HL,BC
        CALL FACE       ;draw a face
        POP BC,HL
        DJNZ PSSU
        POP IY
        RET

;draw a triangular face
FACE                    ;C,D,E-vertex numbers   A-COLOR
        LD (FCOL+1),A
        LD A,C
        ADD A,A
        ADD A,C
        LD L,A
        LD H,'COORDS1   ;first vertex
        LD A,D
        ADD A,A
        ADD A,D
        LD LX,A         ;second
        LD A,E
        ADD A,A
        ADD A,E
        LD LY,A         ;third

        PUSH HL
        INC HL
        LD A,(IX+1)
        SUB (HL)
        LD A,(IY+1)
        SUB (HL)

        INC HL
        LD A,(IX+2)
        SUB (HL)

        LD A,(IY+2)
        SUB (HL)

                        ;IF DY1*DZ2-DZ1*DY2>0 THEN ...
;check whether the face is visible
        PUSH DE         ;calculate the direction of the normal by
        LD A,B          ;the X-coordinate
        LD H,E
        CALL HMULA
        EX (SP),HL
        LD A,H
        LD H,C
        CALL HMULA
        POP DE
        AND A
        SBC HL,DE
        LD A,H
        POP HL
        AND A
        RET M           ;not visible...

        INC HL          ;this one is visible
        LD E,(HL)
        INC HL
        LD D,(HL)

        LD L,(IX+1)
        LD H,(IX+2)

        LD C,(IY+1)
        LD B,(IY+2)
FCOL    LD A,0
        JP TRI          ;draw!!!

RX      DB 0            ;rotation angles
RY      DB 0
RZ      DB 0

Coding (source code)

Fragment 3/6.

;rotation procedure
ROTATE                          ;E-X D-Y C-Z
;----rotate around the Ox axis----------
        LD A,(RX)       ;USING RX
        LD L,A
        LD A,D
        ADD A,MID
        LD H,A
        LD A,(HL)       ;Y*SIN RX
        EX AF,AF'
        LD A,L
        ADD A,64
        LD L,A
        LD B,(HL)       ;Y*COS RX
        LD A,C
        ADD A,MID
        LD H,A
        EX AF,AF'
        ADD A,(HL)      ;Z*COS RX       +Y*SIN RX =Z
        LD C,A
        LD A,L
        SUB 64
        LD L,A
        LD A,(HL)       ;Z*SIN RX
        SUB B
        NEG
        LD D,A

;-----rotate around the Oy axis-------
        LD A,(RY)       ;USING RY
        LD L,A
        LD A,C
        ADD A,MID
        LD H,A
        LD A,(HL)       ;Z*SIN RY
        EX AF,AF'
        LD A,L
        ADD A,64
        LD L,A

        LD B,(HL)       ;Z*COS RY
        LD A,E
        ADD A,MID
        LD H,A
        EX AF,AF'
        ADD A,(HL)      ;X*COS RY       +Z*SIN RY =X
        LD E,A
        LD A,L
        SUB 64
        LD L,A
        LD A,(HL)       ;X*SIN RY
        SUB B
        NEG
        LD C,A

;-----rotate around the Oz axis-------
        LD A,(RZ)       ;USING RZ
        LD L,A
        LD A,E
        ADD A,MID
        LD H,A
        LD A,(HL)       ;X*SIN RZ
        EX AF,AF'
        LD A,L
        ADD A,64
        LD L,A
        LD B,(HL)       ;X*COS RZ
        LD A,D
        ADD A,MID
        LD H,A
        EX AF,AF'
        ADD A,(HL)      ;Y*COS RZ       +X*SIN RZ =Y
        LD D,A
        LD A,L
        SUB 64
        LD L,A
        LD A,(HL)       ;Y*SIN RZ
        SUB B
        NEG
        LD E,A
        RET

COORDS1 DS 256          ;buffer for new coordinates

;----object examples--------
;format: DB number of vertices, number of faces
;        DB X1,Y1,Z1     ;vertex coordinates
;        DB ...
;        DB Xn,Yn,Zn     ;vertices described
;        DB A1,B1,C1,COLOR1 ;vertex numbers for this face
;        DB Am,Bm,Cm,COLORm

;!!!!!!!!!!!!!!!  ATTENTION  !!!!!!!!!!!!!!!!!!!!!!!!!
;
;       All objects must be convex!!!
;
;       Coordinates must be within -32..31
;

;OCTAHEDRON

FIGURE DB 6,8

        DB 0,0,10
        DB 0,-20,0
        DB -20,0,0
        DB 0,20,0
        DB 20,0,0
        DB 0,0,-30

        DB 0,1,2,8
        DB 0,2,3,9
        DB 0,3,4,10
        DB 0,4,1,11
        DB 5,1,4,10
        DB 5,4,3,9
        DB 5,3,2,8
        DB 5,2,1,11

;TETRAHEDRON

FIGUR1  DB 4,4

        DB -22,-22,0
        DB 22,-22,0
        DB 0,22,-22
        DB 0,22,22

        DB 0,2,1,9
        DB 1,2,3,12
        DB 1,3,0,10
        DB 0,3,2,11

;DOUBLE 8-SIDED CONE

FIGUR2  DB 10,16

        DB 0,0,15
        DB -25,0,0
        DB -17,17,0
        DB 0,25,0
        DB 17,17,0
        DB 25,0,0
        DB 17,-17,0
        DB 0,-25,0
        DB -17,-17,0
        DB 0,0,-30

        DB 0,1,2,6
        DB 0,2,3,7
        DB 0,3,4,8
        DB 0,4,5,9
        DB 0,5,6,10
        DB 0,6,7,9
        DB 0,7,8,8
        DB 0,8,1,7
        DB 9,1,8,7
        DB 9,8,7,8
        DB 9,7,6,9
        DB 9,6,5,10
        DB 9,5,4,9
        DB 9,4,3,8
        DB 9,3,2,7
        DB 9,2,1,6

;18-SIDED FIGURE

FIGUR3  DB 26,16+16+8+8

        DB 0,0,15
        DB 11,-11,15
        DB 0,-15,15
        DB -15,0,15
        DB -11,11,15
        DB 0,15,15
        DB 11,11,15
        DB 15,0,15

        DB 21,-21,0
        DB 0,-30,0
        DB -21,-21,0
        DB -30,0,0
        DB -21,21,0
        DB 0,30,0
        DB 21,21,0
        DB 30,0,0

Coding (source code)

Fragment 4/6.

        DB 0,-15,-15
        DB -15,0,-15
        DB 0,15,-15
        DB 11,11,-15
        DB 15,0,-15

        DB 0,0,-15

        DB 0,2,3,14
        DB 0,3,4,14
        DB 0,4,5,14
        DB 0,5,6,14
        DB 0,6,7,14
        DB 0,7,8,14
        DB 0,8,1,14

        DB 10,3,2,10
        DB 11,4,3,10
        DB 12,5,4,10
        DB 13,6,5,10
        DB 14,7,6,10
        DB 15,8,7,10
        DB 16,1,8,10

        DB 2,9,10,8
        DB 3,10,11,8
        DB 4,11,12,8
        DB 5,12,13,8
        DB 6,13,14,8
        DB 7,14,15,8
        DB 8,15,16,8

        DB 9,17,18,8

;procedure for calculating the sine table

;procedure for drawing a textured triangle

TRI                     ;BC,DE,HL-COORDS   H-Y L-X
        ADD A,A
        ADD A,A
        ADD A,A
        LD (RADD+1),A   ;texture addresses
        LD (CADDR+1),A

        LD A,B          ;sort vertices by Y
        CP D
        JR C,O1
        LD B,D          ;BC<->DE
        LD D,A
        LD A,C
        LD C,E
        LD E,A

O1      LD A,D
        CP H
        JR C,O2         ;DE<->HL
        LD D,H
        LD H,A
        LD A,E
        LD E,L
        LD L,A

O2      LD A,B
        CP D
        JR C,O3
        LD B,D          ;BC<->DE
        LD D,A
        LD A,C
        LD C,E
        LD E,A
O3                      ;in order B<D<H
        SUB C
        JR NC,M1
        NEG

        EXX
        LD D,A
        LD E,0
        EXX

        SUB B
        JR NC,M2
        NEG
        JR M3

M1      EXX             ;wild
        LD D,A          ;fixed-point calculations follow
        EXX

        SUB B
        JR NC,M3
        NEG

M2      EXX
        LD C,A
        LD B,E
        CALL Div
        LD A,D
        CPL
        LD D,A
        LD A,E
        CPL
        LD E,A
        INC DE
        JR MOB

M3      EXX
        LD B,E
        CALL Div
MOB     LD (ADX1+1),DE
        EXX

        LD A,L          ;DX2,DX3
        SUB C
        JR NC,M1_
        NEG
        EXX
        LD D,A
        LD E,0
        EXX
        LD A,H          ;DY2,DY3
        SUB B
        JR NC,M2_
        NEG
        JR M3_

M1_     EXX
        LD D,A
        EXX
        LD A,H          ;DY2,DY3
        SUB B
        JR NC,M3_
        NEG
M2_     EXX
        LD C,A
        LD B,E
        CALL Div
        LD A,D
        CPL
        LD D,A
        LD A,E
        CPL
        LD E,A
        INC DE
        JR MOB_

M3_     EXX
        LD B,E
        CALL Div
MOB_    LD (ADX2+1),DE
        LD (ADX3+1),DE
        EXX

        LD A,L
        JR NC,M1A
        NEG
        EXX
        LD D,A
        LD E,0
        EXX
        SUB D
        JR NC,M2A
        NEG
        JR M3A

M1A     EXX
        LD D,A
        EXX
        SUB D
        JR NC,M3A
        NEG
M2A     EXX
        LD C,A
        LD B,E
        CALL Div
        LD A,D
        CPL
        LD D,A
        LD A,E
        CPL
        LD E,A
        INC DE
        JR MOBA

M3A     EXX
        LD B,E
        CALL Div
MOBA    LD (ADX4+1),DE
        EXX
        LD A,B
        EXX
        LD B,A
        AND 7
        LD H,A
        LD A,B
        AND 56
        RLA
        RLA
        LD L,A
        LD A,B
        AND 192
        RRA
        RRA
        RRA
        ADD A,192
        OR H
        LD H,A
        AND 7
RADD    LD DE,CHUNK
        ADD A,E
        LD E,A
        EXX

        LD A,H
        LD (H_+1),A
        LD A,D
        LD (D_+1),A

        LD H,C

Coding (source)

Fragment 5/6.

        SUB B
        JR NZ,P_U
        LD D,E
        LD E,0
        LD L,E
        JR NO1

P_U     LD B,A          ;HIGH1
        LD E,0
        LD L,E

P_UP    LD A,H
        SUB D
        JR NC,COOL
        NEG

        EXX
        INC A
        LD B,A
        EXX

        LD A,H
        JR OTHR
COOL
        EXX
        INC A
        LD B,A
        EXX

        LD A,D
OTHR    CALL P_LIN
        EXX
        LD A,B
        EX DE,HL
ADX1    LD BC,0
        ADD HL,BC
        EX DE,HL

ADX2    LD BC,0
        ADD HL,BC
        LD B,A
        DJNZ P_UP
NO1

H_      LD A,0
D_      SUB 0
        RET Z
        LD B,A

P_DWN   LD A,H
        SUB D
        JR NC,COOL1
        NEG

        EXX
        INC A
        LD B,A
        EXX

        LD A,H
        JR OTHR1
COOL1
        EXX
        INC A
        LD B,A
        EXX

        LD A,D
OTHR1   CALL P_LIN
        EXX
        LD A,B
        EX DE,HL
ADX4    LD BC,0
        ADD HL,BC
        EX DE,HL

ADX3    LD BC,0
        ADD HL,BC
        LD B,A
        DJNZ P_DWN
        RET

P_LIN   EXX             ;textured line drawer
        LD C,A
        AND 248
        RRA
        RRA
        RRA
        ADD A,L
        LD L,A
        LD D,'CHUNK
        LD A,(DE)
        LD (BYT1+1),A
        LD (BYT2+1),A
        LD A,C
        LD C,128
        AND 7
        JR Z,YB
NB      RR C
        DEC A
        JR NZ,NB
YB1
YB      OR C
        RR C
        JR NC,NI
        LD C,A
        CPL
        AND (HL)
        LD D,A
        LD A,(BYT1+1)
        AND C
        OR D
        LD (HL),A
        LD C,128
PCC     INC L
        LD A,B
        SUB 8
        JR C,NI-1
        JR Z,BYT1
        LD B,A
BYT2
        LD (HL),0
        JR PCC
BYT1
        LD (HL),0
        JR NAK

        XOR A
NI      DJNZ YB
        LD C,A
        CPL
        AND (HL)
        LD D,A
        LD A,(BYT1+1)
        AND C
        OR D
        LD (HL),A

NAK
        LD A,L
        AND #E0
        LD L,A
        LD A,E
        INC A
        AND 7
CADDR   OR 0
        LD E,A
        INC H
        LD A,H
        AND 7
        RET NZ
        LD A,L
        ADD A,32
        LD L,A
        RET C
        LD A,H
        SUB 8
        LD H,A
        RET

MULS                    ;HL=H*A
        LD      L,0
        LD      D,L
        LD      E,A
CWERT   DUP     8
        ADD     HL,HL
        ADD HL,DE
        EDUP
        RET

DIVZ    LD DE,0
        POP BC
        RET

Div     PUSH BC         ;DE = DE/BC WITH RESULT ROUNDED
        LD A,B          ;(taken from the BGE 3.05 sources)
        CPL
        LD B,A
        LD A,C
        CPL
        LD C,A
        INC BC
        LD HL,0
        LD A,E
        ADD A,A
        RL D
        DUP 16
        ADC HL,HL
        ADD HL,BC
        JR C,$+4
        SBC HL,BC
        RLA
        RL D
        EDUP
        LD E,A
        POP BC
        SRL B
        RR C
        OR A
        SBC HL,BC
        RET C
        INC DE
        RET

HSINA                           ;A=H*SIN A with sign
        LD D,'SINUS
        LD E,A
        LD A,(DE)
HMULAA  AND A
        JP M,NEGE
        BIT 7,H
        JR Z,ALPOS
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR NEGRES
ALPOS   CALL MULS
        ADD HL,HL
        LD A,H
        RET

NEGE    NEG
        BIT 7,H
        JR Z,NEGRES
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR ALPOS
NEGRES  CALL MULS
        ADD HL,HL
        LD A,H
        NEG
        RET
HMULA   AND A           ;HL=A*H signed
        JP M,NEGE1
        BIT 7,H
        JR Z,ALPOS1
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR NEGRES1
ALPOS1  CALL MULS
        ADD HL,HL
        RET

NEGE1   NEG
        BIT 7,H
        JR Z,NEGRES1
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR ALPOS1
NEGRES1 CALL MULS
        ADD HL,HL
        LD A,H
        CPL
        LD H,A
        LD A,L
        CPL
        LD L,A
        INC HL
        RET

SQR     EQU 4           ;pattern variables
AMPL    EQU 80          ;try experimenting

UZOR                    ;pattern generation
        CALL DECRNT     ;create sine table
        EXX
        LD DE,16384
        LD C,128
        EXX
SHOW    LD C,192        ;Y
        LD HL,TAB
RPO1    LD A,B
        NEG
        LD L,A
        LD A,192
        SUB C
        LD D,A
        ADD A,(HL)
        LD A,L
        LD L,D
        ADD A,(HL)      ;X
        XOR E
        AND SQR
        JR Z,NODOT
        EXX
        LD A,(DE)
        OR C
        LD (DE),A
        EXX
NODOT   EXX
        RRC C
        JR NC,NOIN
        INC E
NOIN    EXX
        DJNZ RPO1
        EXX
        DEC E
        LD A,E
        AND 224
        LD E,A
        CALL D_DE
        EXX
        DEC C
        JR NZ,RPO1
        RET

DECRNT
        LD HL,TAB
DCR1    PUSH HL
        LD H,AMPL
        LD A,L
        CALL HSINA
        POP HL
        LD (HL),A
        INC L
        JR NZ,DCR1
        RET

D_DE    INC D
        LD A,D
        AND 7
        RET NZ
        LD A,E
        ADD A,32
        LD E,A
        RET C
        LD A,D
        SUB 8
        LD D,A
        RET

TAB     EQU 23296

SINUS   INCBIN "SINUS"     ;main sine table
CHUNK   INCBIN "CHUNKDAT"  ;textures

TABL    EQU 32768       ;calculation table

Share your thoughts about the article