Voyager #03
19 октября 1998

Лаборатория - Алгоритм вывода десятичных чисел на экран монитора из регистра DE & HL.

<b>Лаборатория</b> - Алгоритм вывода десятичных чисел на экран монитора из регистра DE & HL.
                 *  *  *


     При написании программ часто требуется вы-
вести числа на экран. Процедуру печати 16-ричных
чисел написать несложно, гораздо труднее обстоит
дело с выводом десятичных чисел. Желательно, чтобы
программа работала как можно быстрее и не имела
больших ограничений на диапазон выводимых чисел.
     Первая процедура как раз и реализует оpиги-
нальный алгоpитм вывода десятичных чисел на экpан
монитоpа из pегистpа DE&HL. Т.е., она преобразует
32-битное число в строку символов.
Данная процедура ориентирована на работу в CP/M,
но, я думаю, что вы легко разберетесь, как исполь-
зовать ее в своих программах и на Спектруме...

        .Z80 
?       EQU 0 


D1836:   DW ? 
D1838:   DB ? 
T1839:   DB ? 


PRINTDEHL: 
        LD     BC,0       ;[BC]:=0 
        LD     (D1836),BC  ;Очистить значения 
        LD     (D1838),BC 
        LD     C,20H      ;For c=1 to 32 
A1433:   ADD    HL,HL 
        RL     E 
        RL     D          ;sla dehl,1 
        PUSH   HL 
        LD     HL,D1836    ;Hачало фоpмиpуемой
                          ;стpоки 
T143C:   LD     B,004H     ;For b=1 to 4 
A143E:   LD     A,(HL)      ;[a]:=([hl]) 
        ADC    A,A        ;[a]:=[a]*2+Carry 
        DAA               ;Десятичн. коppекция
        LD     (HL),A      ;([hl]):=[a] 
        INC    HL         ;[hl]:=[hl]+1 
        DJNZ   A143E      ;Next b 
        POP    HL 
        DEC    C          ;┐
        JR     NZ,A1433   ;┘ Next c 
        LD     BC,0410H   ;[b]:=4;[c]:=16 
        LD     HL,T1839   ;Выводить стpоку с 
                          ;конца 
A144F:   LD     A,(HL)      ;[a]:=([hl]) 
        RRA               ;┐
        RRA               ;├─[a]:=int([a]/16) 
        RRA               ;│ 4 девятибитных
A1453:   RRA               ;┘  сдвига впpаво
        CALL   A1465      ;Выводится младший
                          ;pазpяд
        LD     A,1        ;(бывший стаpший)
                          ;числа
        SUB    B          ;Всего может быть
        JR     NZ,A145D   ;выведено 8 pазpядов
        LD     C,A        ;десятичного числа,
A145D:   LD     A,(HL)      ;если число = 0, то
        DEC    HL         ;должен быть выведен
        CALL   A1465      ;один десятичный pаз-
        DJNZ   A144F      ;ряд, равный нулю
        RET               ;Выход
A1465:   AND    0FH        ;[c]=10h до тех поp,
        JR     Z,A146B    ;пока встpечаются
        LD     C,0        ;(в старших pазpядах)
A146B:   OR     00110000B  ;разряды, равные нулю.
                          ;Таким обpазом, вмес-
        SUB    C          ;то нулевых значений
        PUSH   BC         ;выводятся пpобелы
        PUSH   HL
        LD     E,A        ;выводимый символ
        LD     C,2        ;код функции 'Вывод
                          ;на консоль'
        CALL   5          ;вызов CP/M для
                          ;печати символа
        POP    HL
        POP    BC
        RET





Другие статьи номера:

Информбюро - О планах редакции журнала.

Авторы - Авторы журнала и контакты редакции.

Информбюро - Путеводитель по журналу.

Лоцман - О игре SubSunk.

Лоцман - Описание игры DARK SIDE.

Лодырь - Полное прохождение игры ЗЕРКАЛО.

Калейдоскоп - О игре Пыль звездных дорог.

Калейдоскоп - О втором виртуальном фестивале компьютерного искусства Art Comp-99.

Калейдоскоп - Презентация текстовой утилиты - Text Utility V2.8i.

Скелет - Описание звуковой карты DMA SOUND.

Скелет - Недокументированная особенность процессора Z80.

История - Жизнь после Вилли. Софтография Мэтью Смита.

История - О фидошном слэнге.

Лаборатория - интро POORGUY! - изнутри (исходный текст с комментариями).

Лаборатория - ZX-SPECTRUM и операционные системы.

Лаборатория - Процедуры от MicroSoft.

Лаборатория - Алгоритм вывода десятичных чисел на экран монитора из регистра DE & HL.

Лаборатория - Алгоритм деления и умножения больших чисел.

PROFI CLUB - Изучаем CP/M (совместимость, процессоры, терминалы).

Юмор - Лесенка - советы грамотному юзеру.

Юмор - Стих "OA программистов".

Пишите письма - Письма читателей в журнал.

Реклама - Реклама и объявления ...

ZXTraders - Действyющие распространители программного обеспечения ZX Spectrum по России и Украине


Темы: Игры, Программное обеспечение, Пресса, Аппаратное обеспечение, Сеть, Демосцена, Люди, Программирование

Похожие статьи:
AMIGA NEWS - Амига GFX-чип Permedia2.
Анекдоты - 22 анекдота...
Have a Fun! - Ночной писатель-наркоман.

В этот день...   22 января