Программирование — трёхмерный эффект щупалец на ассемблере

Tagan News #08

Кодинг

В продолжение прошлого разговора о программировании трехмерных штук.

Видели интру к недавно вышедшему InfoGuide? Там на заднем плане крутится такой шарик с «хвостами». Симпатичная штука, носящая красивое название «tentacle effect» («эффект щупальца»). Сегодня мы будем с вами делать нечто похожее.

Нравится? Если да, то готовьте ассемблеры! :)

Так как у нас работает векторная графика, то процедура заливки не нужна, а нужна процедура рисования линии. Я взял готовую (ее в свое время писал один человек из нашей группы, это было довольно давно), поэтому не будем заострять на ней внимание. Все те разговоры о матрицах, пересчете координат, которые были в прошлой статье, актуальны и здесь. Разница только в том, что тогда мы рисовали по граням, а тут будем рисовать по ребрам. Следовательно, процедуры определения видимости нам и даром не нужны, а вот процедура поворота очень даже пригодилась бы. Напоминаю последовательность пересчета координат:

x'=x
y'=y*cos(rx)-z*sin(rx)
z'=z*cos(rx)+y*sin(rx)

Поворот вокруг оси Oy:

x''=x'*cos(ry)+z'*sin(ry) ;вот здесь в прошлой статье неточность
y''=y'
z''=z'*cos(ry)-x'*sin(ry) ;здесь тоже

Вокруг оси Oz:

x'''=x''*cos(rz)-y''*sin(rz)
y'''=y''*cos(rz)+x''*sin(rz)
z'''=z''

А теперь начнем оптимизировать. Направление осей примем следующее: X — вправо, Y — вниз, Z — не важно :) Т.е. используем просто экранные координаты. В итоге все равно будем использовать только X и Y, поэтому слегка упростим себе задачу и отбросим половину вычислений.

x'''=x''*cos(rz)-y''*sin(rz)
y'''=y''*cos(rz)+x''*sin(rz)

Т.к. y''=y', то вокруг Oy будем крутить только X:

x''=x*cos(ry)+z'*sin(ry) ;учитываем, что x'=x

Выходим на финишную прямую:

y''=y*cos(rx)-z*sin(rx) ;потому что y''=y'
z'=z*cos(rx)+y*sin(rx)

Кодинг

Вуаля! В итоге на одну строчку меньше. Мелочь, а приятно и, что самое главное, быстрее!

Задаём объект как набор троек чисел-координат по всем трём осям. При этом делим точки на зоны — по удалённости от центра фигуры. Координаты точек были получены с помощью 3ds Max'a путём создания фигуры, тыкания по её точкам и аккуратного перенесения всех чисел на бумажку.

Точки получили, будем теперь рисовать всю эту тряхомудию (в буквальном смысле, потому как «шшупальца» могут трястись :)). Рисование будет происходить порёберно, одно ребро задаётся индексами двух точек в массиве пересчитанных координат. За подробностями обращайтесь в исходник.

Теперь придадим объекту немного «гибкости». Пускай точки вращаются не синхронно, а «притормаживают» по мере удаления. Реализуется элементарно — заводим три массива углов поворота. В каждый момент времени сохраняем в массивы по одному смещению значения углов поворота. Смещение увеличиваем (циклически всё, зачем память транжирить?). Теперь для того, чтобы реализовать это «торможение», достаточно взять значения из массива по некоторому смещению назад от текущего указателя. Чем дальше залезем назад, тем старее данные получим (главное, не переборщить — массив-то циклический!). Как это реализовано, также смотрим в исходнике.

Несколько замечаний. В этот раз таблица синуса строится несколько по-другому. Если до этого младший байт адреса задавал угол, а от старшего зависела амплитуда (размер таблицы 16 кило, отсюда и ограничение на размер объектов — 32...31 единицы), то теперь всё наоборот. Поэтому немного увеличилась дискретность поворота (pi/32 радиана), потому как значение угла поворота на круг выходит 64, зато ушло ограничение на амплитуду, да и код упростился.

Деморежим сделан просто жутко — бедную кракосямбу плющит и колбасит по всем направлениям, но красиво. Какие батоны надо жать, чтоб всё заработало, читайте в исходнике.

;*
;* LITTLE TENTACLE EFFECT
;*
;* (C) Vitamin/CAIG/2001      11.01.2005
;*
;* ENTER- деморежим
;* O,P, Q,A, W,S- вращение при ручном управлении
;* BREAK- выход
;*

DEMX    EQU 1                   ;три константы для деморежима
DEMY    EQU 3
DEMZ    EQU 5
DOTS    EQU 32                  ;число вершин
SPDX    EQU 3                   ;скорости вращения по осям при
SPDY    EQU 3                   ;ручном управлении
SPDZ    EQU 3
DTS     EQU DOTS*3

        ORG 24576
        LD A,23
        LD BC,32765
        OUT (C),A
        LD HL,49152+6144        ;очистка экрана
        LD BC,767
        LD (HL),56              ;цвет первого
        LDIR
        LD HL,22528
        LD DE,22529
        LD BC,767
        LD (HL),56              ;цвет второго
        LDIR

        OUT (-2),A
;попробуйте сочетание 120,71,0
;обалденно смотрится! :)

        CALL MAK_PLO            ;расчет таблицы для линии
        CALL DECRUNT            ;расчет таблицы синуса
;главный цикл программы
LOOP    CALL CALCUL             ;пересчет координат
PPAG    LD A,23                 ;переключаем экраны
        LD BC,32765
        OUT (C),A
        CALL CLS                ;и стираем что там было
        CALL BUILD

        LD A,(PPAG+1)           ;в следующий раз рисуем на
        XOR 10                  ;видимом экране, а показываем
        LD (PPAG+1),A           ;который будем рисовать сейчас

        LD DE,(RX)              ;углы поворота вокруг осей
        LD BC,(RZ)

Кодинг

Фрагмент 3/6.

DEMO    LD A,-1                 ;деморежим?
        AND A
        JR Z,DRIVE              ;нет, все вручную...
        LD H,'SINUS             ;просто пересчитываем углы...
DX=$+1
        LD L,DEMX
        LD A,(HL)
        SRA A
        SRA A
        SRA A
        SRA A
        SRA A
        ADD A,E
        LD E,A
        LD A,L
        ADD A,DEMX
        LD (DX),A
DY=$+1
        LD L,DEMY
        LD A,(HL)
        SRA A
        SRA A
        SRA A
        SRA A
        SRA A
        ADD A,D
        LD D,A
        LD A,L
        ADD A,DEMY
        LD (DY),A

DZ=$+1
        LD L,DEMZ
        LD A,(HL)
        SRA A
        SRA A
        SRA A
        SRA A
        SRA A
        ADD A,C
        LD C,A
        LD A,L
        ADD A,DEMZ
        LD (DZ),A

        JR ISDEM

DRIVE   LD A,#DF        ;контроль с клавиатуры
        IN A,(#FE)
        JR C,O1
        DUP SPDX
        DEC E
        EDUP
        JR C,O2
        DUP SPDX
        INC E
        EDUP
O2      LD A,#FB
        IN A,(#FE)
        JR C,O3
        DUP SPDY
        INC D
        EDUP
        JR C,O4
        DUP SPDZ
        INC C
        EDUP
O4      LD A,#FD
        IN A,(#FE)
        JR C,O5
        DUP SPDY
        DEC D
        EDUP
        JR C,O6
        DUP SPDZ
        DEC C
        EDUP
O6
ISDEM   LD A,191        ;ENTER- войти/выйти из деморежима
        IN A,(-2)
        RRA
        JR C,NODEM
        LD A,(DEMO+1)
        CPL
        LD (DEMO+1),A
WAYOT   LD A,191        ;подождем пока отпустят...
        IN A,(-2)
        RRA
        JR NC,WAYOT

NODEM                   ;новые углы поворота
        LD (RX),DE
        LD (RZ),BC

        LD H,'XTAB      ;сохраняем историю поворотов
TIMER   LD L,0
        INC L
        LD (HL),E
        INC H
        LD (HL),D
        INC H
        LD (HL),C
        LD A,L
        LD (TIMER+1),A

        CALL 8020       ;нажали BREAK- выход
        JP C,LOOP
        RET

CLS     LD (STAK+1),SP  ;очистка экрана быстрым способом
        DI
        LD HL,0
        LD B,48
PSA
        DUP 64
        PUSH HL
        EDUP
        DJNZ PSA
STAK    LD SP,0
        EI
        RET

;пересчет координат
CALCUL
        LD DE,(RX)      ;запомнили на всякий случай углы
        LD BC,(RZ)
        PUSH DE
        LD HL,ROTDAT
        LD IX,COORDS
        LD A,(TIMER+1)  ;текущий момент времени
        LD E,A
ROTTA   LD A,(HL)
        INC HL
        AND A
        JR Z,RESTZZ
        LD B,A          ;число точек
        LD D,'XTAB
        LD A,E
        SUB (HL)        ;сколько кадров назад это было
        LD E,A
        LD A,(DE)
        LD (RX),A
        INC D
        LD A,(DE)
        LD (RY),A
        INC D
        LD A,(DE)
        LD (RZ),A
        CALL SSG
        INC HL
        JR ROTTA

RESTZZ  POP DE
        LD (RX),DE      ;восстановили углы
        LD (RZ),BC
        RET

;данные по вращению
;сначала 4 точки считаются в реальном времени (ядро)
;затем 12 точек опаздывают на 4 кадра (первый сустав)
;еще 12 точек еще на 4 кадра опаздывают (второй сустав)
;последние 4 точки опаздывают еще на 5 кадров (концы)
;меньшее опоздание делает модель более "упругой"

SSG     EXX             ;пересчет координат
        LD A,(RX)
        AND 252
        RRA
        SCF
        RRA
        LD H,A

        LD B,L
        LD C,(HL)       ;Y*SIN(RX)
        LD E,(HL)       ;Z*SIN(RX)

        LD A,H
        ADD A,16
        AND 191
        LD H,A

        LD A,(HL)       ;Z*COS(RX)
        ADD A,C
        LD C,A          ;Z'= Z*COS(RX)+Y*SIN(RX)

Кодинг

        LD A,(HL)       ;Y*COS(RX)
        SUB E
        LD E,A          ;Y''=Y*COS(RX)-Z*SIN(RX)

        LD A,(RY)
        AND 252
        RRA
        SCF
        RRA
        LD H,A

        LD L,C
        LD C,(HL)       ;Z'*SIN(RY)

        LD A,H
        ADD A,16
        AND 191
        LD H,A

        LD A,(HL)       ;X*COS(RY)
        ADD A,C
        LD C,A          ;X''=X*COS(RY)+Z'*SIN(RY)

        LD A,(RZ)
        AND 252
        RRA
        SCF
        RRA
        LD H,A

        LD L,C
        LD B,(HL)       ;X''*SIN(RZ)
        LD L,E
        LD E,(HL)       ;Y''*SIN(RZ)

        LD A,H
        ADD A,16
        AND 191
        LD H,A

        LD A,(HL)       ;X''*COS(RZ)
        ADD A,B
        ADD A,96
        LD (IX-DTS+1),A ;Y'''
        LD L,C
        LD A,(HL)       ;Y''*COS(RZ)
        SUB E
        ADD A,128

        INC IX
        INC IX
        INC IX
        EXX
        DJNZ SSG
        RET

;построение объекта по координатам точек и списку ребер
BUILD
        LD HL,EDGES
BLDCYC  LD A,(HL)
        INC A
        RET Z           ;последнее ребро?
        DEC A
        LD E,A
        INC HL
        LD A,(HL)
        INC HL
        PUSH HL
        LD L,A
EDGE                    ;L,E-номера вершин ребра
        LD A,L
        ADD A,A
        ADD A,L
        LD L,A
        LD H,'COORDS1
        LD D,H
        LD A,E
        ADD A,A
        ADD A,E
        LD E,A

        LD A,(HL)
        INC HL
        LD H,(HL)
        LD L,A
        EX DE,HL
        LD A,(HL)
        INC HL
        LD H,(HL)
        LD L,A          ;получаем координаты концов ребра
        CALL LINE_R     ;и рисуем его
        POP HL
        JR BLDCYC       ;по всем ребрам

RX      DB 0            ;углы вращения
RY      DB 0
RZ      DB 0
RW      DB 0

COORDS1 DS DTS          ;буфер для пересчитанных координат

;исходный объект
COORDS  DB 0, 0, 10     ;ядро
        DB 9, 0, -3
        DB -5, 8, -3

;первые суставы

        DB 8, 0, -43

;вторые суставы

        DB 5, 0, -73

;концы
        DB 0, 0, -93

;таблица ребер
EDGES   DB 0,1, 0,2     ;ядро
        DB 1,2, 1,3
        DB 3,0, 3,2

;первые суставы

;вторые суставы

;концы

        DB -1

;расчет таблицы синуса
DECRUNT LD HL,#8000
DCR     PUSH HL
        LD A,H
        SUB #80
        ADD A,A
        ADD A,A
        LD H,L
        CALL HSINA
        POP HL
        LD (HL),A
        INC HL
        LD A,H
        CP 192
        JR NZ,DCR
        RET

;всякие служебные процедуры
HSINA                           ;A=H*SIN A
        LD D,'SINUS
        LD E,A
        LD A,(DE)
HMULAA  AND A
        JP M,NEGE
        BIT 7,H
        JR Z,ALPOS
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR NEGRES
ALPOS   CALL MULS
        ADD HL,HL
        LD A,H
        RET

NEGE    NEG
        BIT 7,H
        JR Z,NEGRES
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR ALPOS
NEGRES  CALL MULS
        ADD HL,HL
        LD A,H
        NEG
        RET

HMULA   AND A
        JP M,NEGE1
        BIT 7,H
        JR Z,ALPOS1
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR NEGRES1
ALPOS1  CALL MULS
        ADD HL,HL
        RET

Кодинг

NEGE1   NEG
        BIT 7,H
        JR Z,NEGRES1
        EX AF,AF'
        LD A,H
        NEG
        LD H,A
        EX AF,AF'
        JR ALPOS1
NEGRES1 CALL MULS
        ADD HL,HL
        LD A,H
        CPL
        LD H,A
        LD A,L
        CPL
        LD L,A
        INC HL
        RET

MULS                    ;HL=H*A
        LD L,0
        LD D,L
        LD E,A
CWERT   DUP     8
        ADD HL,HL
        JR NC,$+3
        ADD     HL,DE
        EDUP
        RET

LINE_R  LD (STACK+1),SP ;ПРОЦЕДУРА РИСОВАНИЯ ЛИНИИ
        DI
        LD A,L          ;В HL И DE НАХОДЯТСЯ КООРДИНАТЫ ТОЧЕК
        CP E
        JR NC,NO_EXCH
        EX DE,HL
        LD A,L
NO_EXCH: SUB E
        LD C,A
        LD A,H
        SUB D
        JR C,DOWN_UP
UP_DOWN: LD B,A          ;РИСУЕМ ЛИНИЮ СВЕРХУ ВНИЗ
        LD L,D
        JP MISS
DOWN_UP: NEG             ;РИСУЕМ ЛИНИЮ СНИЗУ ВВЕРХ
        LD B,A
        LD A,191
        SUB D
        LD L,A
MISS:   ADD HL,HL
        LD SP,HL
        LD H,'LIN_ARR
        LD L,D
        LD A,(HL)
        INC H
        LD D,(HL)
        INC H
        LD L,E
        ADD A,(HL)
        LD E,A
        INC H
        LD L,(HL)
        EX DE,HL
        LD A,B
        CP C
        JR NC,VERTIC
HORIZON: DEFB 221        ;ГОРИЗОНТАЛЬНАЯ ЛИНИЯ (DX>DY)
        LD L,A
        DEFB 221
        LD H,C
        LD B,C
        LD C,E
        LD A,B
        SRL A
        JR Z,END_LIN
        EX AF,AF'
HORIZ0: LD A,(HL)
        OR C
        LD (HL),A
        EX AF,AF'
        DEFB 221
        SUB L
        JR NC,HORIZ2
        DEFB 221
        ADD A,H
        POP DE
        ADD HL,DE
HORIZ2: EX AF,AF'
        RRC C
        JR NC,HORIZ1
        INC L
HORIZ1: DJNZ HORIZ0
END_LIN: LD A,(HL)
        OR C
        LD (HL),A
STACK:  LD SP,0
        EI
        RET
VERTIC: DEFB 221        ;ВЕРТИКАЛЬНАЯ ЛИНИЯ (DY>DX)
        LD H,A
        DEFB 221
        LD L,C
        LD C,E
        SRL A
        JR Z,END_LIN
        EX AF,AF'
VERT0:  LD A,(HL)
        OR C
        LD (HL),A
        EX AF,AF'
        DEFB 221
        SUB L
        JR NC,VERT1
        DEFB 221
        ADD A,H
        RRC C
        JR NC,VERT1
        INC L
VERT1:  EX AF,AF'
        POP DE
        ADD HL,DE
        DJNZ VERT0
        JP END_LIN
DEFB    " * MEGA FAST LINE V1.0 BY UNWINDER'95
NEXT_DE: INC D
        LD A,D
        AND 7
        RET NZ
        LD A,E
        ADD A,32
        LD E,A
        RET C
        LD A,D
        SUB 8
        LD D,A
        RET
MAK_PLO: LD HL,LIN_ARR
        LD B,192
MAK_PL0: LD (HL),E
        INC H
        LD (HL),D
        DEC H
        INC L
        CALL NEXT_DE
        DJNZ MAK_PL0
        LD HL,LIN_ARR+1023
        LD A,1
MAK_PL1: LD (HL),A
        RLCA
        DEC L
        DJNZ MAK_PL1
        DEC H
        LD A,31
MAK_PL2: LD B,8
MAK_PL3: LD (HL),A
        DEC L
        DJNZ MAK_PL3
        DEC A
        JP P,MAK_PL2
MAK_LIN: LD IX,LIN_ARR+1024
        LD B,191
MAK_LI0: LD E,L
        LD D,H
        EX DE,HL
        CALL NEXT_DE
        EX DE,HL
        AND A
        SBC HL,DE
        LD (IX),L
        INC IX
        LD (IX),H
        INC IX
        ADD HL,DE
        DJNZ MAK_LI0
        LD IX,LIN_ARR+1024+512
        LD B,191
MAK_LI1: LD E,L
        LD D,H
        CALL PREV_HL
        AND A
        SBC HL,DE
        LD (IX),L
        INC IX
        LD (IX),H
        INC IX
        ADD HL,DE
        DJNZ MAK_LI1
        RET
PREV_HL: DEC H
        LD A,H
        AND 7
        CP 7
        RET NZ
        LD A,L
        SUB 32
        LD L,A

Кодинг

        RET C
        LD A,H
        ADD A,8
        LD H,A
        RET

SINUS   INCBIN "SINUS
XTAB    EQU $                   ;история вращения по X

Поделитесь вашим мнением о статье