ZXNet эхоконференция «code.zx»

Привет, Denis!

Суббота 31 Мар 2001, в 15:14:32,
Denis Kitel -> All:

DK> Moжет есть у кого драйвер верхней памяти под КAY-1024 для
DK> TRMSHOB2? Или хотябы
DK> под 256К, а то у меня глючный какойто. Кинте плз.

Вот под Скорп с часами:

╒═══< Begin file: trmsdrv .asm >══════════

;Драйвер расширенной памяти TRMSDRV C
;Рассмотрим этот драйвер на примере
;Scorpion, где страницы 8-15 выбираются
;установкой 4-го бита порта #1FFD в "1",
;и не будем использовать 2,5,8 и 9 стра-
;ницы (всего страниц 16-4 = 12).

ORG #5B00

DEFB 12 ;к-во использ. страниц
JR C,TIME
PAGE PUSH BC ;точка вызова драйвера
PUSH HL
LD HL,PAGES ;таблица страниц
ADD A,L ;A-логич. номер страницы
LD L,A
LD A,(HL)
AND 16
LD BC,#1FFD
OUT (C),A
LD A,(HL)
OR 16
LD B,#7F
OUT (C),A
POP HL
POP BC
RET

PAGES DEFB 0,1,3,4,6,7
DEFB #12,#13,#14,#15,#16,#17

; Длина драйвера не должна превышать
;127 байт. Разрешается менять только ре-
;гистровую пару AF. Hа выходе флаг нуля
;Z должен быть в состоянии NZ.
;При наличии микросхемы реального време-
;ни есть возможность записывать текущие
;дату и время при записи MS-DOS файлов
;вместо даты 28.02.00 и времени 21:20.
; Реализация реального времени:
;при переключении страниц делается
;CALL #5B01 со сброшеным флагом C. Перед
;записью заголовка MS-DOS файла делается
;CALL #5B01 с поднятым флагом C, а в
;A - текущая страница. Таким образом
;поддерживается совместимость со старым
;драйвером TRMSDRV.
; И-так, порядок действий:
;- если флаг C=0, то включаем страницу,
; номер которой находится в регистре A
;- если флаг C=1, то записать в нижепе-
; речисленные регистры следующие значе-
; ния:
; B - час (0-23)
; C - минута (0-59)
; D - месяц (1-12)
; E - день (1-31)
; L - год (0-99)
; Внимание! Если микросхема реального
;времени хранит значения в BCD формате,
;то их нужно перевести в HEX формат!

TIME LD D,%00100000
RST 8 : DB #89
LD C,B : LD B,E
PUSH BC
LD D,%00100001
RST 8 : DB #89
LD L,E
LD E,C
LD D,B
POP BC
RET

╘═══< End file: trmsdrv .asm >════════════


Приятных коннектов Denis...