ZXNet эхоконференция «code.zx»

Hемедленно нажми на RESET, Igor!

10 Sep 00 22:22, Igor Kiselev wrote to All:

IK> У кого-нить есть следущая процедура, очень нужна. Желательно
IK> быструю.
IK> Hа входе в HL число, на выходе разложеное по байтам это же
IK> число.
IK> вход : рег-тр HL=#C000
IK> выход: память +0 #34 - "4"
IK> +1 #39 - "9"
IK> +2 #31 - "1"
IK> +3 #35 - "5"
IK> +4 #32 - "2"

Сам напpосился, вот тебе быстpая:

Сpазу пpедупpеждаю -- можно ещё быстpее, тут записывание в буфеp тоpмозное.

=== Cut ===
─ Personal mail (2:5030/827.2) ───────────────────────── X.PERSONAL (CODE.ZX) ─
Msg : 71 of 97 Rcv
From : Aleksey Malov 500:8362/1.3 26 Aug 00
To : Kirill Frolov 31 Aug 00
Subj : Идейка сфоpмиpовалась ;)
───────────────────────────────────────────────────────────────────────────────
* Forwarded from area 'CODE.ZX'

Приветствую тебя, Kirill!

Thu 24 Aug 2000 в 15:47:48 Kirill Frolov и Aleksandr Majorov разговаривали
на тему Идейка сфоpмиpовалась ;).

KF> Всего 1621 тактов на пеpевод числа!
KF> 2All: Кто может быстpее?
Сам напросился. У меня за 636 тактов (если не ошибаюсь).

;in: hl - число
;out: по адресу buffer представление числа на входе в виде ascii строки (без
отбрасывания незначащих нулей)

bin2asc ld b,0

ld a,h
rlca
rlca
rlca
ld h,a
and 7 ;34

rl h
adc a,a
daa

rl h
adc a,a
daa

rl h
adc a,a
daa
;82
rl h
adc a,a
daa
rl b

rl h
adc a,a
daa
rl b

rl l
adc a,a
daa
rl b
;154
rl l
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a
;190
rl l
ld a,c
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a

rl l
ld a,c
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a

rl l
ld a,c
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a
;310
rl l
ld a,c
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a
rl d

rl l
ld a,c
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a
rl d
;406
rl l
ld a,c
adc a,a
daa
ld c,a
ld a,b
adc a,a
daa
ld b,a
ld a,d
rla
and 7
;461
ld de,#0f30
ld hl,buffer
add a,e
ld (hl),a
inc hl
;498
ld a,b
rrca
rrca
rrca
rrca
and d
add a,e
ld (hl),a
inc hl

ld a,b
and d
add a,e
ld (hl),a
inc hl
;564
ld a,c
rrca
rrca
rrca
rrca
and d
add a,e
ld (hl),a
inc hl

ld a,c
and d
add a,e
ld (hl),a
ret ;636

buffer ds 5

Счастливо, Kirill! С вами был Vivid/Brainwave^X-Project.
[ZX] [Sailor Moon]
-+- Lara Croft за 4.50 $.
+ Origin: Multik will be the best! (500:8362/1.3)

=== Cut ===