ZXNet эхоконференция «code.zx»


тема: блочник рамдиска для пентагонов 512-1024



от: Oleg Grigoriev
кому: Kirill Frolov
дата: 22 Dec 1998

Пусть враги твои, Kirill, умрут без сыновей!

21-12-98 в 05:13:19 Kirill Frolov ═> Oleg Grigoriev:

KF> В исдосе надо как можно больше блочник, но чтобы банки 0...7 не юзались
KF> - они надо для isunzjr, Dickie етц. А банка 15 aka #57 самая главная -
KF> это как в скорпе 8-ая. В ней STS хочется посадить и по магику туда
KF> вываливаться. Дык вот надо сделать так, чтобы банка с STSом юзалась в
KF> последнюю очередь. За 0 блок желательно принимать 8 банку.

KF> Тут для 512, а в случае метра будет еще и 5 бит of #7ffd заюзан.

Все сделал вроде так как ты описал. Кстати, мог и сам напи-
сать - у меня это заняло ровно 24 минуты. Hиже идут ююк и ис-
ходник. В блочнике по смещению +#49 надо прописать количество
страничек минус 8. Собственно, должен работать на пне 256,
512, 1024. Числа - 8, 24, 56. Банки переключаются в районе
LLL.
Адрес - как обычно.

section 1 of 1 of file ed_pent8.blk < iS-UUE 1.00 by MK >

begin 644 ed_pent8.blk
M```*@`V`N(#X!J8`C[K,G:`,J&`?(`H!/[`.`0^!S?)\LCRQ++(L2(G&`
M>P/QL!GKV^43WB1*`8X`T<8!$BO&/EZV<8(_@`@!#X/&`7^#R`!/%_F.`<'
MRR^8'L@']?^UYV7H(>!$``$$.``#MH.V@[:#MH.V@[:#MH.V@
M[:#MH.V@[:#MH.V@[:#MH.IW@* 9_7_M>:_[R?__`8`#@`6`#X`2@"J`EX"G@("G
`
end
sum -r/size 65502/315 section (from "begin" to "end")
sum -r/size 58465/205 entire input file

=== begin of file ed_pent8.as ===
;ed_pent8.blk
;ramdisk driver for pentagon with 256, 512, 1024 Kb memory
;(c) Oleg Grigoriev AKA Ruiner AKA #0R
;Version: 1.0
;Complete: 100%
;Creating date: 22-12-98
;Last edit:
;%--543210 : logic num
;%435--210 : mask for #7ffd

ORG #8000

DEFW #0000
DEFW LOAD
DEFW SAVE
DEFW INIC
DEFB %11111000
DEFB %00000110
;-----------------------------
LOAD XOR A
JR $+#04
;-----------------------------
SAVE LD A,#EB
LD (LLLL),A
LD (MMMM),A
LD A,H
ADD A,B
JR Z,E_EXIT
CP #C0
JR C,$+#06
E_EXIT LD A,#07
SCF
RET
;----------------;
DI

SLA E
RL D
SLA E
RL D
LD (LLL2+#01),HL
LD A,E
RRCA
RRCA
ADD A,#C0
LD H,A
MOVE XOR A
LD L,A
SUB H
LD C,A
LD A,B
SUB C
JR Z,LL1
JR C,LL2
LL3 LD B,A
JR LLL
;-----------------------------;
LL2 LD C,B
LL1 XOR A
JR LL3
;-----------------------------;
LLL
LD A,D
EXX
ADD A,#08
CP #00 ;8,24,56
JR NZ,INCA0
LD A,#0F ;BANK WITH STS
JR INCA1

INCA0 CP #0F
JR NZ,$+#03
INC A

INCA1 LD E,A
AND %00111000
RLCA
RLCA
SLA A
JR NC,$+#04
OR #20
OR #10
LD D,A
LD A,E
AND #07
OR D
LD BC,#7FFD
OUT (C),A

EXX
LD A,D
EX AF,AF'
LD A,B
LLL2 LD DE,#0000
LD B,C
LD C,#00
LLLL DEFB #00
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
JP PE,$-#20
AND A
JR Z,MOVE1
LD B,A
EX AF,AF'
LD C,A
LD A,#00
MMMM EQU $-#01
AND A
JR NZ,$+#04
LD H,D
LD L,E
LD (LLL2+#01),HL
LD D,C
INC D
LD H,#C0
JR MOVE
;-----------------------------;
MOVE1 EX AF,AF'
LD A,#10
LD BC,#7FFD
OUT (C),A
INIC XOR A
EI
RET

=== end of file ===

С наилучшими пожеланиями, Олег aka Ruiner.




Темы: Игры, Программное обеспечение, Пресса, Аппаратное обеспечение, Сеть, Демосцена, Люди, Программирование

Похожие статьи:
Amiga New`s - Heкoтoрыe нoвoсти oт прoизвoдитeлeй жeлeза - Phаse5 и Вlittersoft.
Оттяг - Полезное о сексе.
Игры - прохождение игры Iron Lord .

В этот день...   23 октября