ZXNet эхоконференция «code.zx»


тема: исходник блочника РД



от: Oleg Grigoriev
кому: all
дата: 18 Jul 1998

Hello, all !

Hате. И делайте там всякие проверки/восстановления/буфе-
ра... сколько влезет.

=====cut=====
;21-01-98
;ed_gmx0.blk
;(c)Ruiner
;Last edit: 23-04-98
;
ORG #8000
;-----------------------------;
DEFW #0000 ;п/п инсталяции драйвера
DEFW LOAD ;п/п чтения блока
DEFW SAVE ;п/п записи блока
DEFW INIC ;п/п инициализации драйвера
DEFB %11111000 ;
DEFB %00000110
;-----------------------------;
LOAD XOR A
JR $+#04
;-----------------------------;
SAVE LD A,#EB
LD (LLLL),A
LD (MMMM),A
;-----------------------------;
LD A,H
ADD A,B
JR Z,E_EXIT
CP #C0
JR C,$+#06
E_EXIT LD A,#07
SCF
RET
;----------------;
SLA E
RL D
SLA E
RL D
LD (LLL2+#01),HL ;D-BANK,HL=DEST
LD A,E
RRCA
RRCA
ADD A,#C0
LD H,A
MOVE XOR A
LD L,A ;HL=откуда
SUB H ;сколько блоков из этой банки
LD C,A ;можно перебросить
LD A,B ;всего надо перебросить
SUB C
JR Z,LL1
JR C,LL2
LL3 LD B,A
JR LLL
;-----------------------------;
LL2 LD C,B
LL1 XOR A
JR LL3
;-----------------------------;
LLL DI ;B=остаток,C=сколько
LD A,D
ADD A,#09
EXX
LD D,A
LD E,A
LD BC,#7FFD
AND #07
OR #10
OUT (C),A
LD B,#1F
LD A,D
AND #08
RLCA
OUT (C),A
LD A,E
LD B,#DF
RLCA
RLCA
RLCA
RLCA
AND #07
OUT (C),A
EXX ;B=остаток,C=сколько
LD A,D
EX AF,AF'
LD A,B
LLL2 LD DE,#0000 ;DE=куда
LD B,C
LD C,#00
LLLL DEFB #00
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
LDI
JP PE,$-#20
AND A
JR Z,MOVE1
LD B,A
EX AF,AF'
LD C,A
LD A,#00
MMMM EQU $-#01
AND A
JR NZ,$+#04
LD H,D
LD L,E
LD (LLL2+#01),HL ;HL=SOURCE
LD D,C
INC D
LD H,#C0
JR MOVE
;-----------------------------;
MOVE1 EX AF,AF'
INIC LD BC,#7FFD
LD A,#10
OUT (C),A
XOR A
LD B,#1F
OUT (C),A
LD B,#DF
OUT (C),A
EI
RET
=====cut=====


С наилучшими пожеланиями, Олег aka Ruiner.




Темы: Игры, Программное обеспечение, Пресса, Аппаратное обеспечение, Сеть, Демосцена, Люди, Программирование

Похожие статьи:
Новости - Делегация в составе Tot,T(c)S,AlCo,John отправилась на "запорожце" Tot'а в гости к KSA-7G. И другие Рязанские новости.
Incoming - новые игры: Mojon Twins' Covertape #1, Willy Meets The Beatles, VADE RETRO, RodLand (in color).
Интервью - Screamer.

В этот день...   15 октября