ZXNet эхоконференция «code.zx»
тема: Scorpion Rom ASpect Newspaper
от: 500:812/08.14
кому: Oleg Grigoriev
дата: 27 Feb 1998
Hi, Oleg !
Tут какой-то спор...
OG> Если тебе надо абсолютно безглючный способ вытаскивания
OG> #1f, #3f, #5f, могу кинуть.
Кинь. это будет полезно всем. И прекратит ненужные споры.
А мне интересно... Зачем вытаскивать регистры #3ф,5ф,7ф?
Hафиг они нужны? Пускай сидят внутри...
Максимум, что может понадобиться - регистр дорожки.
Я делаю через установку INTRQ. В десять строчек. А ты?
И по поводу #1ф напиши. Я пользую два места.
Одно - когда не важно, какие биты, а важно наличие ошибки.
И другое - нормальное, но геморрой с #5цц2.
Всего хорошего.
Дмитрий aka -=LD=- / X-TRADE GROUP.
-+- SMM version 1.08
от: 500:812/17.09
кому: Alexandr Knyzev
дата: 28 Feb 1998
Hello, Alexandr!
27-02-98 в 12:50 Alexandr Knyzev писал(а) к Oleg Grigoriev
на тему "Scorpion Rom Re:ASpect Newspaper".
OG>> Если тебе надо абсолютно безглючный способ вытаскивания
OG>> #1f, #3f, #5f, могу кинуть.
AK> Буду премного благодарен ;)
Тебе я вроде объяснил. Hу ладно:
;------------------------------------;
FR_PR5F PUSH HL,DE,BC ;OUT: A=IN (#5F)
LD (FR_P05F+#01),SP
LD A,#C3
LD HL,FR_P05F
LD (#5CC2),A
LD (#5CC3),HL
LD IX,#3F72
PUSH IX
DI
JP #3D2F
FR_P05F LD SP,#0000
POP BC,DE,HL
RET
;------------------------------------;
FR_PR3F PUSH HL,DE,BC ;OUT: A=IN (#3F)
LD (FR_P03F+#01),SP
LD A,#C3
LD HL,FR_P03F
LD (#5CC2),A
LD (#5CC3),HL
LD IX,#3F69
PUSH IX
DI
JP #3D2F
FR_P03F LD SP,#0000
POP BC,DE,HL
RET
;------------------------------------;
FR_PR1F PUSH HL,DE,BC ;OUT: A=IN (#1F)
CALL FR_PR3F
LD D,A
LD (FR_P01F+#01),SP
LD A,#C3
LD HL,FR_P01F
LD (#5CC2),A
LD (#5CC3),HL
LD IX,#2740
PUSH IX
DI
JP #3D2F
FR_P01F LD SP,#0000
POP BC,DE,HL
LD A,(#5CCD)
RET
;------------------------------------;
И еще неплохо было бы иметь по адресу #5cb6 #f4. В принципе
он там всегда, но вдруг ты переменные потрешь. Дык с ним быст-
рее будет.
AK> Hу я просто решил вычислить, прав ли Кирилл или мне в клинику пора..
Тебе-то врядли.
С наилучшими пожеланиями, Олег aka Ruiner.
-+- Брысь-Edit v6.06
|