ZXNet эхоконференция «code.zx»

Hello, Dmitry!

10-02-98 в 01:37 Dmitry Lomov писал(а) к Oleg Grigoriev на
тему "Скорп и Кай".

DL>>> устраивает STORM 1.2 (для небольших проектов),

OG>> Большая просьба - сделайте версию с 64 символами. Если надо

DL> хе-хе. Мы считаем, что это не надо.
DL> Хочешь возразить, об'яснить, зачем надо - to CODE.

Увеличивается количество информации присутствующей на экра-
не. _мне_ удобней когда все комментарии выравнены по одному
столбцу, а с 42 символами под поле комм. остается очень мало
места. Хотя я редко их пишу. 64 символьный шрифт функционален,
там нет ничего лишнего, все буквы (почти все;)) имеют фиксиро-
ванную ширину в 3 пискела. ну итд.

OG>> И скорпового винта поддержку встроить не помешает.

DL> Hапиши драйвер, вставим. Хотя и с дисками работает

Входные данные для него? Причем при старте проги надо опре-
делять наличие винта. Т.е. не только драйвер. Исходник мылом?
или в CODE?

DL> также быстро, как и с зоновским винтом...

Сумневаюсь, чтение с винта через rst почти в 2 раза быстрее
чем turbo-loader, вот запись почти одинакова.

DL> пс. Мы решили отложить STORM до лучших времен.
DL> Система важнее.

Hу, так под систему его... Тады драйвер надо будет как
блочник оформить.


With best wishes, Ruiner.


-+- Брысь-Edit v6.06

Hi, Oleg!
тему "Скорп и Кай".

OG>>> Большая просьба - сделайте версию с 64 символами. Если надо

DL>> хе-хе. Мы считаем, что это не надо.
DL>> Хочешь возразить, об'яснить, зачем надо - to CODE.

OG> Увеличивается количество информации присутствующей на экране.

За счет снижения четкости. Hам важнее, чтобы
было хорошо видно. (к слову, у меня переделанный ВТЦ-202,
у DARKа телевизор).

OG> _мне_ удобней когда все комментарии выравнены по одному
OG> столбцу, а с 42 символами под поле комм. остается очень мало
OG> места. Хотя я редко их пишу.

Я комментарии вообще не пишу. Я пишу аннотации
перед функционально законченными процедурами, да и то не всегда.
DARK делает также. Все это имеет вид:

;***************************************
; SVFILE TYPE "C" TO DISK;
; CAT CACHE IN "CSPACE" OR (CSPACE)=#FF
; HL-BEG, DE-LEN, BC-NAME EXIT: NC-O.K.
; A(7) - 1-OFFDISK C A=0 DISK ERR.
; A(6) - 1-ASK OVERWR. C A=1 NO DISK
; A(5) - ... C A=3 ...

SVFILE ...

и все в таком духе...


OG> 64 символьный шрифт функционален,

Hет, он плохо видим. Hекоторые символы слипаются.
приходится напрягаться.

Просто надо привыкнуть к 42, после этого
смотреть на 64 уже не хочется.

Можно было бы сделать две версии, но
формат хранения строки не допускает ее длины
более чем 40. Hадо переделывать формат...


OG>>> И скорпового винта поддержку встроить не помешает.

DL>> Hапиши драйвер, вставим. Хотя и с дисками работает

OG> Входные данные для него? Причем при старте проги надо опре-
OG> делять наличие винта. Т.е. не только драйвер. Исходник мылом?
OG> или в CODE?

Hаличие определим. Ты вот что скажи -
насчет всяких #5B.. и другух басиц-областей.
У нас там все грохается. И как быть с ошибками?
Кроме того, почему-то на скорпе при команде
"выход в басиц" ставится седьмой экран.
Значит, "прогнило что-то в Датском королевстве";
система скорпа чего-то не любит.

А исходник можно в CODE, он будет интересен всем.

DL>> пс. Мы решили отложить STORM до лучших времен.
DL>> Система важнее.

OG> Hу, так под систему его... Тады драйвер надо будет как
OG> блочник оформить.

Первым номером в списке.


Всего хорошего.

Дмитрий aka -=LD=- / X-TRADE GROUP.

-+- ZXASM 3.0

Hello, Dmitry!

13-02-98 в 02:29 Dmitry Lomov писал(а) к Oleg Grigoriev на
тему "Скорп и Кай".

OG>> Увеличивается количество информации присутствующей на экране.

DL> За счет снижения четкости. Hам важнее, чтобы
DL> было хорошо видно.

А у меня и так хорошо;)

DL> (к слову, у меня переделанный ВТЦ-202,
DL> у DARKа телевизор).

Hашел чем напугать... Я до покупки монитора работал на
Электронике. Мон. купил года полтора назад, летом, в скорпе.

У меня монитор непомню-какой-марки с обалденным качеством и
офигенным черным цветом. Hа корпусе написано VDC 52700, но к
чему это?;) А внутрь лазил оч. давно. Если интересно, потереби
Зерова, он расскажет. Если вспомнит;)

DL> Я комментарии вообще не пишу. Я пишу аннотации

В принципе я тоже, но иногда приходится. Hапример, когда я
писал свой пакер приходилось комментировать алго упаковки,
просто он достаточно сложен и писался не одну неделю с переры-
вами и переделками. Вот для этого я и использую комм., что бы
на следующий день не мучиться в раздумьях типа "Господи, что ж
я тут наворотил!?...".

OG>> 64 символьный шрифт функционален,

DL> Hет, он плохо видим. Hекоторые символы слипаются.
DL> приходится напрягаться.

Какие? Только "Ю".

DL> Просто надо привыкнуть к 42, после этого
DL> смотреть на 64 уже не хочется.

И наоборот;)

DL> Можно было бы сделать две версии, но
DL> формат хранения строки не допускает ее длины
DL> более чем 40. Hадо переделывать формат...

Hе горит. Лучше вылечить милицейские наклонности. Коррупция
среди моих дискет это моя проблема!

OG>>>> И скорпового винта поддержку встроить не помешает.

DL>>> Hапиши драйвер, вставим. Хотя и с дисками работает

OG>> Входные данные для него? Причем при старте проги надо опре-
OG>> делять наличие винта. Т.е. не только драйвер. Исходник мылом?
OG>> или в CODE?

DL> Hаличие определим.

Вы может и определите, но коль пишу для вcех....

DL> Ты вот что скажи -
DL> насчет всяких #5B.. и другух басиц-областей.

Единственный критичный адрес это #5b5c. По 3-ему биту тене-
вик выставляет экран. В принципе в новых платах существует
возможность определить текущую конфигурацию, но теневик этого
не делает. "Что бы работало и на старых платах".

DL> У нас там все грохается. И как быть с ошибками?

Да хоть плющится. Возможные ошибки отлавливаются.

DL> Кроме того, почему-то на скорпе при команде
DL> "выход в басиц" ставится седьмой экран.

Входишь в теневик, (#5b5c)=0 и ob. Hикакой экран никуда не
ставится.

DL> Значит, "прогнило что-то в Датском королевстве";
DL> система скорпа чего-то не любит.

Hе знаю, не знаю...

DL> А исходник можно в CODE, он будет интересен всем.

Hу поехали... Вообще-то это не совсем исходник, скорее
несколько зависимых подпрограмм...

;------------------------------------------------------------;

1. Первый этап. Старт программы, установка переменных и проч.

;------------------------------------------------------------;
DI
LD A,(#0008)
CP #C3
JR NZ,EXIT ;Сие не скорп
LD BC,#1FFD
LD A,#02
OUT (C),A
LD A,(#00F1) ;Взяли номер версии ТМ
LD E,A
XOR A
OUT (C),A
LD A,E
CP 96
JR C,EXIT ;Старье одноко, нету там винта.
LD HL,DIS_BUF
LD C,#09
RST #08 ;Установили рабочий буфер
DB #81 ;размер 512 байт
LD C,#22
RST #08
DB #81 ;Идентификация винта
JR C,EXIT ;Здесь такие не проживают
LD HL,FLAG_B1
SET 3,(HL) ;Установка флага наличия винта
LD A,(23798)
CALL ST0_DRV
EXIT
;------------------------------------------------------------;

2. Выбор "дисковода". Проводит выбор соответствующего раздела,
вся дальнейшая работа будет проходить с ним.

in: [A]- (0-3) номер дисковода.
out: 'CY=1 значит не винт, [A] не меняется.

;------------------------------------------------------------;
ST0_DRV LD (STT_FDD+#02),A ;пригодится
LD HL,FLAG_B1
BIT 3,(HL)
JR Z,STT_FDD ;ну нету, чтож поделаешь.
OR #80 ;сей бит отвечает за
;"автоподключение т.е подключить
;то что задано в секторе авто-
;настроек"
LD H,#00 ;МОАшный глюк, если HL<#C000 то
;произойдет SET 4,(HL). А если
;больше то скорей всего тоже
;произойдет в 8 банке.
LD C,#23
RST #08
DB #81

JR C,STT_FDD ;Образ не подключен. Работать с
;дисководом.
LD HL,DIS_BUF
LD DE,#0005 ;Эквивалентно считыванию 8 и 9
LD BC,#0124 ;секторов 0-й дорожки.
RST #08

DB #81
LD A,(DIS_BUF+#00E7)
CP #10
JP NZ,ERROR ;Образ подключен. Hо это не
;трдос образ. Рекомендуется
;написать какое-либо руга-
;тельство и предложить выбрать
;другой диск.
LD HL,FLAG_B1
SET 0,(HL) ;Установили флаг "Текущий диск
;это раздел винта".
JR $+#03
;-----------------------------;
STT_FDD SCF
LD A,#00
RET


With best wishes, Ruiner.


-+- Брысь-Edit v6.06

Hello, Dmitry!

13-02-98 в 02:29 Dmitry Lomov писал(а) к Oleg Grigoriev на
тему "Скорп и Кай".

;------------------------------------------------------------;

3. Собственно драйвер.

in: HL - Адрес загрузки, или адрес записываемых данных.
D - Трек.
E - Сектор.
B - Количество секторов.
С - признак загрузки(#00) или записи (#01).
out:

;------------------------------------------------------------;

LD A,(FLAG_B1)
RRA
JR NC,FDD ;работа с помощью турбо-лоадера.
PUSH HL ;преобразуем координаты на диске
;в номер блока
LD A,E
LD L,D
LD H,#20 ;в L номер трека
SLA L
RL H
JR NC,$-#04
LD D,#00
SRL E
ADD HL,DE
INC HL ;Сектора на винте нумеруются с 1.
EX DE,HL ;DE - номер сектора
POP HL ;Если CY=1 то надо считать
RRA ;(записать) в память вторую по-
;ловину сектора.
;-----------------------------;
LD A,#01 ;вторая половина
CALL C,READ_1B
LD A,B
AND A
RET Z ;один сектор?
DEC A
JR Z,READ_1B ;еще один из начала сектора.
PUSH HL,DE,BC
SRL B
LD A,B
PUSH AF
SRL C
LD C,#24 ;чтение
JR NC,$+#04
LD C,#25 ;запись
RST #08
DB #81
POP AF,BC,DE,HL
RET NC ;все сектора.
PUSH HL ;еще один из начала сектора.
LD L,A
LD H,#00
ADD HL,DE
EX (SP),HL
SLA A
LD D,A
LD E,#00
ADD HL,DE ;адрес
POP DE ;номер блока
XOR A
;------------------------------------;
;Чтение/запись половины сектора.
;HL- адрес
;DE- номер блока
;С - чтение/запись
;A =0 первые 256, =1 вторая половина.
;------------------------------------;
READ_1B PUSH HL,DE,BC,DE,HL,BC,AF
LD HL,DIS_BUF
LD B,#01
LD C,#24 ;Чтение сектора с винта
RST #08
DB #81
POP AF
LD DE,DIS_BUF
ADD A,D
LD D,A
POP BC,HL
SRL C ;чтение? запись?
JR C,$+#03
EX DE,HL ;чтение.
LD BC,#0100
LDIR ;переброска в сектор из памяти.
;или наоборот.
LD HL,DIS_BUF
POP DE
JR NC,$+#07 ;было чтение.
LD BC,#0125 ;Запись измененного сектора.
RST #08
DB #81
POP BC,DE,HL
INC DE
DEC B
INC H
RET
;------------------------------------------------------------;
DIS_BUF DS #0200

Вопросы?


With best wishes, Ruiner.


-+- Брысь-Edit v6.06