ZXNet эхоконференция «code.zx»

Смотрю вдруг 13-12-97, в 02:43:36, Oleg Grigoriev писал к ALL:

Hi Oleg!

OG> Для корректной отработки задержек при
OG> работе с дисководом очень хотелось бы пои-
OG> меть список _программных_ способов отклю-
OG> чения/включения/переключения turbo-режима
OG> на различных видах spectrum-совместимых
OG> компьютеров.

ну на скорпе ты наверно знаешь:

turbo_on: ld bc,#7ffd
in c,(c)

turbo_off: ld bc,#1ffd
in c,(c)

на АТМ (turbo) (2) (2+)

turbo_on: ld a,171
ld bc,10835
push bc
ld bc,#ff77
jp 15663

turbo_off: ld a,163
ld bc,10835
push bc
ld bc,#ff77
jp 15663

на профи нет програмного метода переключения turbo_on/off
на каы как то через #1ffd. так что придтся табе еще и
тип машины определять перед работой. попробуй AUTOconfig из
ZF,SPF,on_line... или мне напиши кину в эху последнюю версию.

▌▌║▌█▐│▌▌▐▐ WiTh The BeST wIsheS fROM
▌▌║▌█▐│▌▌▐▐ *C*R*E*A*T*O*R*
▌812/03.00▐


-+- SMM version 1.05

Смотрю вдруг 26-12-97, в 04:09:40 некто
Oleg Grigoriev писал к Paul Falcon про Hе корысти ради, а токмо пользы для... :

Hi Oleg !

PF>> нет, не люблю "." нажимать (в xas'e вместо "#" можно точку
PF>> ставить он сам исправляет)

OG> Эх, блин, в нем бы шрифт заменить, да с винтом подружить...
OG> :) Хочешь, дрювер напишу? около 3 секов... 512 байт - буфер
OG> [на винте сектора 512 байт:(] ну и loader/saver байт 200. А?;)
OG> А то до сих пор пишу в четвертом тасме. Он хоть и работает с
OG> винтом через #3d13 :(, но при чтении (то бишь ассемблировании)
OG> обгонит:) любой захудалый шторм:( (42 символа в строке -
OG> ssssssuuuuuuuuuuuuxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxxx!!!!!).

xas и 64 символьный есть... а вот с винтом проблема,
чтото не очень он хочет через #3d13 работать... глюкует при
записи. будет время разберусь.

PF>> страничками ничего не проверяется! это все не 100%
PF>> может это старый скорпион без теневика. а надписи
PF>> в пзу дело не серьезное потому как могли смениться.

OG> А если сделать out (#1FFD),#02? Hа скорпе это подключает
OG> ПЗУ Expansion. Чего это делает на кае не известно, но даже ес-
OG> ли и подключает 2 банк ROM , то он наверняка чистый. Таким об-
OG> разом взять десяток байт из ПЗУ и сравнить с нулем. А если не
OG> подключает то взять тот же 10-к шелкнуть и сравнить.

а если на другой машине это сглючит о тест улетит к
едрене фене?

OG> Hу кинь ты в эху свой автоконфиг. Hе хочешь GMX делать -
OG> сам сделаю. Hе так уж сложно, благо процедура уже написана,
OG> надо только состыковать.

щас, тока сконеверчу.

вот:

;IY-127 MACHINE TYPE
;IY-126 ALL PAGES
; 0 =1 #7FFD SPECTRUM 128K
; 1 =1 #1FFD SCORPION OR KAY
; 2 =1 #DFFD PROFI
; 3 =1 TURBO 2+
; 4 =1 #FDFD ATM TURBO 1
; 5 =1 6 & 7 bit #7FFD
; 7 =1 #08 BYTE #C3

START
XOR A
LD (IY-127),A
INC A
LD (IY-126),A
DI
LD A,(#08)
CP #C3
JR NZ,ITURBO
SET 7,(IY-127)
ITURBO LD HL,(1111)
LD BC,#FFF7
LD A,%00011111
CALL OUTC_A
LD DE,(#C000+1111)
AND A
SBC HL,DE
LD BC,#FFF7
LD A,255
CALL OUTC_A
JR NZ,IDFFD
SET 3,(IY-127)
JR I7FFD
IDFFD LD HL,#80
LD DE,#1000
LD BC,#DFFD
OUT (C),D
LD A,(HL)
INC (HL)
CP (HL)
OUT (C),E
JR Z,I1FFD
SET 2,(IY-127)
JR I7FFD
I1FFD LD DE,#1110
LD B,#1F
OUT (C),D
LD A,(HL)
INC (HL)
CP (HL)
OUT (C),E
JR Z,IFDFD
XOR A
OUT (C),A
SET 1,(IY-127)
JR I7FFD
IFDFD LD B,C
LD HL,#FFFF
OUT (C),D
LD B,#7F
OUT (C),D
LD (HL),D
LD B,C
OUT (C),E
LD B,#7F
OUT (C),D
LD (HL),E
LD B,C
OUT (C),D
LD B,#7F
OUT (C),D
LD A,(HL)
CP D
JR NZ,I7FFD
SET 4,(IY-127)
I7FFD LD HL,#80
LD DE,#1000
LD BC,#7FFD
OUT (C),D
LD A,(HL)
OUT (C),E
CP (HL)
OUT (C),D
JR Z,SIZED
SET 0,(IY-127)
SIZED CALL VIRT
LD A,(IY-126)
CP 8
JR C,ENDING
LD A,(IY-127)
CP 1
JR NZ,ENDING
SET 5,(IY-127)
ENDING LD A,0
CALL EX_RAM
EI
RET
VIRT LD IX,#C000
LD HL,DOOM+63
LD B,64
V_R11 LD A,B
DEC A
CALL EX_RAM
LD C,(IX+0)
LD (HL),C
LD (IX+0),A
DEC HL
DJNZ V_R11
PUSH AF
LD (IY-126),61
POP AF
LD DE,TABL_PG
V_R20 LD A,(DE)
CP #FF
JR Z,V_R30
CALL EX_RAM
CP (IX+0)
JR Z,V_R22
PUSH DE
LD HL,TABL_PG+62
AND A
SBC HL,DE
PUSH HL
POP BC
PUSH DE
POP HL
INC HL
LDIR
DEC (IY-126)
POP DE
DEC DE
V_R22 INC DE
JR V_R20
V_R30 LD B,64
LD HL,DOOM
V_R31 LD A,64
SUB B
CALL EX_RAM
LD A,(HL)
LD (IX+0),A
INC HL
DJNZ V_R31
RET
DEBUG PUSH DE
POP HL
NO_PG1 DEC DE
LD A,(DE)
CP #FF
JR Z,NO_PG2
CP C
JR NZ,NO_PG1
SBC HL,DE
PUSH HL
POP BC
PUSH DE
POP HL
INC HL
LDIR
DEC (IY-126)
DEC HL
DEC HL
NO_PG2 EX DE,HL
RET
ONPAGE PUSH BC
PUSH HL
LD C,A
LD B,0
LD HL,TABL_PG
ADD HL,BC
LD A,(HL)
POP HL
POP BC
EX_RAM DI
PUSH HL
PUSH AF
PUSH BC
BIT 1,(IY-127)
JR NZ,ZS256
BIT 2,(IY-127)
JR NZ,PROFI
BIT 3,(IY-127)
JR NZ,TURBO_2
BIT 4,(IY-127)
JR NZ,ATM1
JR SPECCY
TURBO_2 PUSH AF
PUSH IX
AND 24
CPL
LD BC,#FFF7
CALL OUTC_A
POP IX
POP AF
JR SPECCY
ATM1 LD BC,#FDFD
PUSH AF
RRCA
RRCA
RRCA
AND 3
JR HOME
PROFI LD BC,#DFFD
PUSH AF
RRCA
RRCA
RRCA
AND 7
JR HOME
ZS256 PUSH AF
LD B,A
AND %00001000
RLCA
LD C,A
LD A,B
AND %00110000
RLCA
RLCA
ADD A,C
LD BC,#1FFD
HOME OUT (C),A
POP AF
SPECCY LD B,A
AND 24
RLCA
RLCA
RLCA
LD C,A
LD A,B
AND 7
ADD A,C
OR 16
LD BC,#7FFD
OUT (C),A
POP BC
POP AF
POP HL
RET
OUTC_A LD IX,10835
PUSH IX
JP 15663
DEFB #FF
TABL_PG DEFB 00,01,03,04,06,07
DEFB 08,09,10,11,12,13,14,15
DEFB 16,17,18,19,20,21,22,23
DEFB 24,25,26,27,28,29,30,31
DEFB 32,33,34,35,36,37,38,39
DEFB 40,41,42,43,44,45,46,47
DEFB 48,49,50,51,52,53,54,55
DEFB 56,57,58,59,60,61,62,63
DEFB #FF
DOOM DEFS 64


PF>>>> ▌▌║▌█▐│▌▌▐▐ WiTh The BeST wIsheS fROM CREATOR product

OG>>> Слушай, всё забываю спросить, а чей ты
OG>>> продукт? ;)

PF>> мой!

OG> Сам себя сделал?! Ж:) Бей изврашенцев!;)

это ващето торговая марка aka копиригхт!

по поводу ис-доса, покидай мылом зипы, на MAS BBS, а то
я толко ночью свободен. с часа гдето. да и драйврра
рам дисков посмотри - мне очень надо много и разных

▌▌║▌█▐│▌▌▐▐ WiTh The BeST wIsheS fROM CREATOR product
▌812/03.00▐ Powered by Cyrix 6x86L 200+/16DIMM/S3TrV2 2MB/1.6GB


-+- SMM version 1.05